need help on declaring variables

Hi Monks,

I put the following code to run on a linux box and tried to run it but it gave me some error

use strict;
use warnings;
use DateTime::Format::Strptime;
my $Strp = new DateTime::Format::Strptime(pattern     => '%Y-%b-%d %T'
+,);
my $infile = 'log.txt';
my $outfile = 'report.txt';
my($fh_out, $fh);
my %lookup;
my $channel = 'TWO';
my $time_delta = 3600;  # seconds = 1 hour
open($fh_out, '>', $outfile) or die "Could not open outfile: $!";
open($fh, '<', $infile) or die "Could not open logfile: $!";
while (<$fh>) {
    next unless /$channel/;
    $_ =~ m/^(.*) UTC.*refs = (\d+)$/;
    my $dt = $Strp->parse_datetime($1);
    my $timestamp = $dt ->epoch();
    my $refs = $2;
    if ( defined($lookup{$refs}) && $lookup{$refs} + $time_delta <= $t
+imestamp ) {
        print $fh_out "REFS $refs: occurrences at " . $lookup{$refs} .
+ "and $timestamp \n";
        print "REFS $refs: occurrences at " . $lookup{$refs} . " and $
+timestamp \n";
    }
    $lookup{$refs} = $timestamp;
}
close $fh_out;
#close $fh;
[download]

The error seems to stem from here

    my $dt = $Strp->parse_datetime($1);
    my $timestamp = $dt ->epoch();
    my $refs = $2;
[download]

the $1 and $2 ...

I wonder where did i go wrong ...

Comment on need help on declaring variables Select or Download Code
Re: need help on declaring variables by Thilosophy (Curate) on Mar 03, 2008 at 06:48 UTC
but it gave me some error Hmm. Did it give you an error message to go along with the error? The error seems to stem from here: `my $dt = $Strp->parse_datetime($1); my $timestamp = $dt ->epoch(); my $refs = $2;` [download] You suspect $1 and $2. Do they contain the value you think they should (add some debug output)? When using regular expressions, you should check if there actually was a match.	[reply] [d/l]
Re^2: need help on declaring variables by tuakilan (Acolyte) on Mar 03, 2008 at 07:31 UTC
hi thilosophy, the error which i got when run the script is `Can't call method "epoch" on an undefined value at comblog.pl line 52, + <$fh> line 5.` [download]	[reply] [d/l]
Re: need help on declaring variables by ysth (Canon) on Mar 03, 2008 at 07:38 UTC
First, check that the regex match actually succeeded, don't just assume and go on to use $1 and $2. Second, pass "$1", not $1. See Re: Tainting problem on Strawberry perl and its parent. -- Online Fortune Cookie Search	[reply]
Re: need help on declaring variables by almut (Canon) on Mar 03, 2008 at 08:34 UTC
`$_ =~ m/^(.) UTC.refs = (\d+)$/; my $dt = $Strp->parse_datetime($1); my $timestamp = $dt ->epoch(); my $refs = $2;` [download] ...third (in addition to what ysth said), don't use `$1`, `$2`, etc. after some code which could have modified those variables in the meantime (like the `$dt->epoch()` call here — I'm not saying that it did modify `$2`, but code under the hood of that call could have...). Best only use them immediately after the match, or store the value away in some other variable.	[reply] [d/l] [select]
Re: need help on declaring variables by peterdragon (Beadle) on Mar 03, 2008 at 09:05 UTC
The line `my $dt = $Strp->parse_datetime($1);` [download] is returning undef because the input string in $1 is in an incorrect format. Either change the declaration of Strp like `my $Strp = new DateTime::Format::Strptime(pattern => '%Y-%b-%d %T' +, on_error => 'croak');` [download] to throw an error in that case or check for it in your code by replacing the line starting 'my $dt...' with `unless (my $dt = $Strp->parse_datetime($1)) { warn "invalid datetime: $1"; next; }` [download] -- peterdragon ~ http://perl.dragonstaff.co.uk	[reply] [d/l] [select]
Re: need help on declaring variables by stiller (Friar) on Mar 03, 2008 at 09:24 UTC
Wariation over a theme...., change: `$_ =~ m/^(.) UTC.refs = (\d+)$/; my $dt = $Strp->parse_datetime($1); my $timestamp = $dt ->epoch(); my $refs = $2; if ( defined($lookup{$refs}) && ....` [download] to: `my ($dt, $timestamp, $refs); if ( m/^(.) UTC.refs = (\d+)$/ ){ # right here, just after the match, is the only # place it's safe to use $1 and $2 - tuck them away: my $t = $1; $refs = $2; $dt = $Strp->parse_datetime($t); $timestamp = $dt ->epoch(); } else { warn "No match: $_ \n"; next; } if ( defined($lookup{$refs}) && ....` [download] Edit: corrected an error (my'ing $refs twice)	[reply] [d/l] [select]
Re: need help on declaring variables by hipowls (Deacon) on Mar 03, 2008 at 09:35 UTC
When using regular expressions it is usually a good idea to put them in a condition. `if ( my ( $raw_dt, $refs ) = /^(.) UTC.refs = (\d+)$/ ) { my $dt = $Strp->parse_datetime($raw_dt); ... } else { # possible error condition }` [download] The greater danger of your code, apart from using uninitialized $1 and $2, is using an initialized $1 and $2 from a previous match. The capture buffer variables $1 etc are not reset to undef when a match fails so you may produce erroneous output without any outward sign.	[reply] [d/l]


P is for Practical
	PerlMonks

need help on declaring variables

The best material for plates (tableware) is: