merging content based on common columns of 2 files using grep

[heidi]

hi all, I have 2 files, and i want to merge based on the column which is common to both the files. here are my input files:

file1:
TST_01  sp|123|fts
TST_02  sp|3438|rvs
TST_03  sp|2744|rtp

file2:
file1:
sp|123|fts  checked_proved
sp|3438|rvs  proven_right
sp|2744|rtp  un_proved

desired result file:
TST_01  sp|123|fts  checked_proved
TST_02  sp|3438|rvs  proven_right
TST_03  sp|2744|rtp  un_proved

#!/usr/bin/perl
open(FH1,file1.txt);
open(FH2,file2.txt);
@array=<FH2>;

while($var=<FH1>){
  ($first,$second)=split("\t",$var);
  @grepped= grep ("$second",@array);
  print "$first\t@grepped\n";
}

can any one help? thank you.

[citromatik]

First of all, you should use strict; and use warnings; if you want to learn Perl the easy way

There are some errors in your code, some of them:

• file1.txt and file2.txt are literal strings, so you should put them in quotation marks
• After read a file, you should chomp the line/s read
• The syntax you are using for grep is not correct, you should be using grep BLOCK LIST

Here is a working version of your program:

use strict;
use warnings;

open(FH1,"file1.txt");
open(FH2,"file2.txt");
my @array=<FH2>;
chomp @array;

while(my $var=<FH1>){
  chomp $var;
  my ($first,$second)=split(/\s+/,$var);
  my @grepped= grep {/\Q$second\E/} @array;
  print "$first\t$grepped[0]\n";
}

You should also consider using hashes to solve your problem

Another alternative, if the script is only going to join both files and output the result (and you are in a Unix/Linux system, as it seems to be the case) is to use bash's join tool:

$ join -1 2 -2 1 file1.txt file2.txt

[heidi]

thank u :)

[targetsmart]

what is the output you got?, what is the problem you faced?.
UPDATE
from the code you shown above, it won't work as you expected. because for every line(first column) in the file1 you are printing the only the second column match from file2.
grep will give only the matched indexes in this case
use hash instead
iterate through the second file and load the splitted line into a hash like the first column as key and second column as value(provided your second file is not in huge size)
then when you are iterating the first file, just check exists in the hash, if exists append the hash value as the third column during print
hope this helps

[heidi]

The output was giving only the second column of the first file as results :(

[Anonymous Monk]

Copy+Paste is your friend, friend :)

[planetscape]

Have a look at Corion's most excellent join - join two files according to a common key. Sounds like it will do exactly what you want.

[bichonfrise74]

Try this...

#!/usr/bin/perl

use strict;

my %hash;

my $raw_file_1 = <<FILE_1;
file1:
TST_01  sp|123|fts
TST_02  sp|3438|rvs
TST_03  sp|2744|rtp
TST_04  sp|0123|not_here
FILE_1

my $raw_file_2 = <<FILE_2;
file2:
sp|123|fts  checked_proved
sp|3438|rvs  proven_right
sp|2744|rtp  un_proved
sp|0000|bogus bogus
FILE_2

open( my $file_1, "<", \$raw_file_1 ) or die "Couldn't open \$raw_file
+_1\n";
while (<$file_1>) {
    next if /^file/;
    my ($val, $key) = split;
    $hash{$key} = $val;
}

open( my $file_2, "<", \$raw_file_2 ) or die "Couldn't open \$raw_file
+_2\n";
while (<$file_2>) {
    next if /^file/;
    my ($key, $val) = split;
    print "$hash{$key}\t$key\t$val\n" if ( defined($hash{$key}) );
}