Array shortcut

[Anonymous Monk]

I want to add a whole range of things to an array instead of typing them all out. The below has a serious syntax error. Can you help me get it to work? I also want to include the SPACE character, too.

#!/usr/bin/perl

use warnings;
use strict;

my @chars = qq(a-z, A-Z, 0-9, !, @, #, $, %, ^, &, *);

print @chars;

[GrandFather]

Not so much a serious syntax error as a serious semantic error. You are creating a string using qq where what you really want is a list of characters. To compound the problem qq interpolates so $, (the output field separator special variable) is interpolated but generates a 'Use of uninitialized value in concatenation (.) or string at ...' warning because it is undef by default.

You can achieve what you intend with:

use warnings;
use strict;

my @chars = ('a'..'z', 'A'..'Z', '0'..'9', '!', '@', '#', '$', '%', '^
+', '&', '*');

print @chars;

Prints:

abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789!@#$%^&*

[kennethk]

By using chr, you can recover a character from its index in the character set. You can therefore use that in combination with Range Operators in order to generate the kind of list you are looking for. For example:

#!/usr/bin/perl

use warnings;
use strict;

my @chars = map chr($_), 32 .. 122;

print @chars;

outputs

 !"#$%&'()*+,-./0123456789:;<=>?@ABCDEFGHIJKLMNOPQRSTUVWXYZ[\]^_`abcdefghijklmnopqrstuvwxyz

[jettero]

You can actually do some of them without needing chr. my @a = ('a' .. 'z');

my @a = ('a'..'z', 'A'..'Z', 0..9, qw(! @ # $ % ^ & *), ' '); # maybe?

Just another way to do it.

UPDATE: Or you could disable that warning. It is just a warning afterall.

[toolic]

and avoid a warning by pulling '#' out of qw:

my @chars = ('a' .. 'z', 'A' .. 'Z', 0 .. 9, '#', ' ', qw(! @ $ % ^ & 
+*));

[YuckFoo]

I'd rather split single-quoted strings, easier to write (and read) than all the '',...',,'.. ,',' ,..', ', stuff. It's not like there is an endless supply of comma and quote.

#!/usr/bin/perl

  use strict;

  my @chars = (
    split('', 'abcdefghijklmnopqrstuvwxyz'),
    split('', 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'),
    split('', '0123456789!@#$%^&* '),
  );

  print @chars;