No you're not. You can only pass strings via ARGV

Is there any other way of doing this? Also If I am passing a scalar varaible and an array from define.pl then it works fine. Only when I am passing the reference parameters it is giving this problem.

Can you please explain in more I didnt understood what do you mean by "All you're passing are the stringified references. If you want to pass entire datastructures on the command line, use a serializer, and pass the serialized data on the command line. Deserialize in the called program."

Can you please modify the code to help me understand this.

To understand what was meant by "All you're passing are the stringified references", change your code like this:

#!/usr/bin/perl

# program.pl

use warnings;
use strict;

my @array1 =( 1..3 );
my @array2 = ( 4..6 );

my $ref_array1 = \@array1;
my $ref_array2 = \@array2;

system("./print.pl",$ref_array1,$ref_array2);
[download]

...and the print.pl:

#!/usr/bin/perl

use strict;
use warnings;

my ( $ref_string1 ,$ref_string2 ) = @ARGV;

print "$ref_string1, $ref_string2\n";
[download]

...and run it.

You can use 'Storable' to save your data serialized into a file, and then have the print program lift it back up:

#!/usr/bin/perl

use warnings;
use strict;

use Storable;

my @array1 = ( 1..3 );
my @array2 = ( 4..6 );

my $store_file = './data.store';

# encapsulte the two arrays into a single array ref
# for storage. We'll extract in print.pl

store( [ \@array1, \@array2 ], $store_file );

# instead of passing the data as the parameters, pass the file name in
+stead

system( "./print.pl", $store_file );
[download]

...and the print....

#!/usr/bin/perl

use strict;
use warnings;

use Storable;

my $store_file = $ARGV[0];

# we have to extract the two original arrays from the
# single array that we encapsulated them in

my $aoa = retrieve( $store_file );
my ( $aref1 ,$aref2 ) = @{ $aoa };

print "@{ $aref1 }, @{ $aref2 }\n";
[download]

Hope this helps!

Steve

Change

system("print.pl",$ref_array1,$ref_array2);
[download]

to

print "Array 1: $ref_array1\nArray 2: $ref_array2\n";
[download]

And run, you'll see what you're passing to the second script.

A suggested you'll have to provide the contents of the arrays rather than references to the second script.

I'm not sure you really want to do what you think you are doing. Your code would be much cleaner, faster, and do what you mean if you kept it all in one script and used subs, like so:

use strict; use warnings;

my @array1 = ( 1 .. 3 );
my @array2 = ( 4 .. 6 );

print2arrs( \@array1, \@array2 );

sub print2arrs {
  my ( $ref1, $ref2 ) = @_;
  print @$ref1;
  print @$ref2;
}
[download]

And if you really do need to keep them in separate files, check out require or do to avoid using the system command and firing off an entirely new perl interpreter

Hi Steve, Thanks for the piece of code.

What I am working upon: 1) Parsing ~100 of XML files 2) The information which is extracted is kept in an different arrays 3) Info available in the arrays is entered into an excel sheet.

Thats what I was exploring with this small piece of code.

I guess you think that your array references are some kind of pointers to memory locations, and you want to access that memory structures from another program.

Even if you could pass that memory addresses to the second program, I'm not sure you'll succeed, I think that OS will prevent that.

Off-Topic: I remember doing something like that successfully on an old multiuser machine years ago. I forced a logout of another user by clearing he's assigned memory area using Pascal.  >:-)

Shaing memory could be done by using IPC::Shareable and passing the assigned '$glue' to the 'print.pl' (or whatever) script.

Just a something something...