Re: [threads] Open a file in one thread and allow others to write to it

This opens a file, starts 4 threads; writes to that file from all 4 threads (with locking) at random for a short while then stops the threads. It then reopens the file and prints it to stdout:

#! perl -slw
use strict;
use Time::HiRes qw[ time sleep ];
use threads;
use threads::shared;

our $THREADS ||= 4;

my $sem :shared;
open LOG, '>', 'log.txt' or die $!;


sub logit {
    lock $sem;
    return printf LOG @_;
}

sub thread {
    my $tid = threads->self->tid;
    my $stop = shift;
    warn $tid, ": starting:", time(), " Stoptime: $stop\n";
    while( sleep( rand( 1 ) ) && time() < $stop ) {
        logit "%2d: The time is %f\n", $tid, time;
    }
    warn $tid, ": stopping at ", time(), "\n";
}

my @threads = map
    threads->create( \&thread, time() + int( rand 10 ) ),
    1 .. $THREADS;

warn "threads started; waiting\n";
$_->join for @threads;

warn "threads done\n";

open LOG, '<', 'log.txt' or die $!;
print while <LOG>;
close LOG;
[download]

What more do you need?

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

RIP PCW It is as I've been saying!(Audio until 20090817)

Comment on Re: [threads] Open a file in one thread and allow others to write to it Download Code

Replies are listed 'Best First'.
Re^2: [threads] Open a file in one thread and allow others to write to it by Gangabass (Vicar) on Nov 16, 2009 at 13:13 UTC
Sorry, you didn't understand me (my error). Of course i know that file handler is cloned between threads. But i need more: i need to open file handler in the thread and allow other threads to write to it. Or shortly i need a solution to write to log file (from each thread). This is easy. But i'm also need to check for log size. So if it arrive some value i need to close old log file and open new one. And this event (maximum log file) occur in one of the thread (i have shared variable which increment after each write to log).	[reply]
Re^2: [threads] Open a file in one thread and allow others to write to it by gulden (Monk) on Nov 16, 2009 at 12:51 UTC
A Filehandle can't be shared between threads. http://www.cpanforum.com/posts/11104 ŤA contentious debate is always associated with a lack of valid arguments.ť	[reply]
Re^3: [threads] Open a file in one thread and allow others to write to it by BrowserUk (Patriarch) on Nov 16, 2009 at 12:58 UTC
S'funny, cos the code I posted is very well tested (going back to 5.8.0 and right upto 5.8.9 & 5.10.1 (64-bit)! The mistake you're making is reading "Filehandles cannot be made 'shared'." to mean 'filehandles cannot be shared'. Those phrases do not be not mean the same thing. Filehandles are process global entities and therefore can be cloned. Which means that each thread created after a filehandle comes into existance gets it's own copy of the global. Try the code I posted. Tell me how you get on :) Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error. "Science is about questioning the status quo. Questioning authority". In the absence of evidence, opinion is indistinguishable from prejudice. RIP PCW It is as I've been saying!(Audio until 20090817)	[reply]
Re^4: [threads] Open a file in one thread and allow others to write to it by gulden (Monk) on Nov 16, 2009 at 13:14 UTC
This is our endless discussion. ŤFilehandles cannot be made 'shared'ť, maybe in your OS it works, not in the OS's i've tested. When you clone the Filehandle you are assuming that OS will sync the File->writes without any race conditions problems, but that is not true. Updated: This is what happens when removing the sleep()'s: `1: The time is 1258377733.481062 1: The time is 1258377733.481164 1: The time is 1258377733.481337 1: The time is 1258377733.4 3: The time is 1258377733.473267 3: The time is 1258377733.473595 3: The time is 1258377733.473749 3: The time is 1258377733.473885 3: The time is 1258377733.474008 3: The time is 1258377733.474110 3: The time is 1258377733.474212 3: The time is 1258377733.474313` [download] In high concurrency level, the problems appear. ŤA contentious debate is always associated with a lack of valid arguments.ť	[reply] [d/l]
Re^5: [threads] Open a file in one thread and allow others to write to it by BrowserUk (Patriarch) on Nov 16, 2009 at 13:23 UTC
Re^6: [threads] Open a file in one thread and allow others to write to it by gulden (Monk) on Nov 16, 2009 at 13:37 UTC
Some notes below your chosen depth have not been shown here


Just another Perl shrine
	PerlMonks