It's not entirely clear to me what you are trying to do, but in case you're looking for motifs: MEME may be more efficient. Both binaries and webinterface are available here:

MEME website

You could probably do better using regular expressions with Global matching. Without completely understanding what you mean by "slight mismatches," (please explain!) I think something like this would accomplish your exact matches:

UPDATE: using scalar where I did was wrong.

@_=qw;
Just another Perl hacker,;
;$_=q=print
"@_"= and eval;
[download]

Yes, the direct matches are not a problem. I am glad you could confirm the code. For the mismatch code I mean: I have a hash value which is a DNA sequence, example:
TGATTGAA

If my % threshold was .75 for example, and if I was searching for TGAT, I would like for the program to tell me that there able for the program to find the identical match at position 1, AND identify the second match at position 5 as an "acceptable mismatch".

With respect to your suggestion of regexp...Is it possible to type those in on the command line? Currently I use @ARGV[0] as my $search query, typically something like "ATC".
Thanks! ER

Your second question is much easier: Yes. Regular expressions can be built from any string, including those supplied by users. Generally, you should use quotemeta or the \Q and \E markers to make sure the string is free from regular expression meta characters like *, ., and more evil eval-type expressions. In your case, you could also check that the string is a valid nt sequence:

my $string = quotemeta shift;
die "Not a valid nucleotide sequence" if $string =~ /[^AGTC]/;
[download]

As for the first question, one way would be to build a regex for each possibility. An example:

my $string = "TGAT";
my @nts = map { 
    my $tmp = $string;
    substr $tmp, $_, 1, '.';
    $tmp;
    } (0 .. length ($string) -1);
my $groupings = join '|', @nts;

my $sample = "TGATTGGAATGTTAGAT";

while ( $sample =~ /($groupings)/go )
{
    print "Matched $1 ending at position ", pos $sample, "\n";
}
[download]

---

@_=qw;
Just another Perl hacker,;
;$_=q=print
"@_"= and eval;
[download]

Something like this?

$seq = 'TGTGTGTGTGTG';;
@tests = qw[ TX TXXX ];;
for my $test ( @tests ) {
    ( my $re = $test ) =~ tr[X][.];
    print "'$1'" while $seq =~ m[(?=($re))]g;
};;
'TG'
'TG'
'TG'
'TG'
'TG'
'TG'
'TGTG'
'TGTG'
'TGTG'
'TGTG'
'TGTG'
[download]

Replacing your 'X's with '.'s gives you a wildcarding ability.

By placing the capture inside a lookahead, the matchpoint will only be advanced by one position after each match, rather than the length of the match. That allows overlapping matches to be found.

My favorite trick for this sort of fuzzy matching is to combine bit wise xor and the transliteration operator (used in this context for counting). Consider:

use strict;
use warnings;

my $target = 'TGATTGAATCAAGGTGTTTT';
my $match = 'TGAT';
my $quality = 0.75;
my $matchLen = length $match;
my $matchNum = int ($matchLen * $quality);

for my $offset (0 .. length ($target) - $matchLen) {
    my $test = substr $target, $offset, $matchLen;
    my $matched = ($test ^ $match) =~ tr/\x00//;

    next if $matched < $matchNum;
    print "Found <$test> at offset $offset which matches in $matched p
+laces\n";
}
[download]

Prints:

Found <TGAT> at offset 0 which matches in 4 places
Found <TGAA> at offset 4 which matches in 3 places
Found <TGTT> at offset 14 which matches in 3 places
[download]

The only problem with that is the threshold is not exact, for example, if the threshold is instead .5, and the length of the query is three characters, I still come up with all the matches that have at least (1/3). I have tried fixing this to no avail, here is my attempt:

foreach my $key (keys %o) {
my $keydisplay=1;
my $target = $o{$key};
#my $threshold = 0.79;
my $searchlength = length $search;
my $truethreshold = int($searchlength * $threshold*100) /100; #(page46
+)

    if ($searchlength - $truethreshold >= .005) {
$truethreshold += .01;
}
$searchlength = $truethreshold;


for my $position (0 .. (length ($target) - $searchlength)) {
    my $test = substr $target, $position, $searchlength;
    my $matched = ($test ^ $search) =~ tr/\x00//;

next if $matched < $truethreshold;
    print "\t\tFound <$test> at position $position which matches in $m
+atched of $searchlength places\n";
  }
}
[download]

Characters are discrete entities. What outcome do you expect from matching 1/2 a character?

---

True laziness is hard work

use strict;
use warnings;
use Text::Levenshtein qw(distance);

my $text = 'TGATTGAA';
my $search = 'TGAT';
my $fuzz = 1; # how far off a match can we be

for my $start (0..(length($text) - length($search)) ) {
  my $chunk = substr($text,$start,length $search);
  print "checking for $search from position $start: $chunk: ";
  my $dist = distance($search, substr($text, $start, length $search));
  if($dist == 0) {
    print "Match!\n";
  }elsif($dist <= $fuzz) {
    print "Close enough\n";
  }else{
    print "nope\n";
  }
}
[download]

checking for TGAT from position 0: TGAT: Match!
checking for TGAT from position 1: GATT: nope
checking for TGAT from position 2: ATTG: nope
checking for TGAT from position 3: TTGA: nope
checking for TGAT from position 4: TGAA: Close enough