#!/usr/bin/perl

use strict;
use Data::Dumper qw/Dumper/;

my $text = <<EOT;
fourscore and score years ago, we scored great scores in
apple cores.  it's time for an encore at the core of our cultural
centre.  in many centres where we travelled, Johann hasn't
scored as well as he did in Johannesburg, where his score
against Johannes Brahms shook us to our cores.
EOT

my %edit;
while (<DATA>) {
    chomp;
    my ( $word, $repl, $stops ) = split /\t/;
    next unless ( length( $word ) and length( $repl ));

    my ( $pref_len, $suff_len ) = ( 0, 0 );
    my @stops = split( /,/, $stops );
    for my $stop ( @stops ) {
        my ( $pref, $suff ) = map { length( $_ ) } split( /\Q$word\E/, $stop );
        $pref_len = $pref if ( $pref_len < $pref );
        $suff_len = $suff if ( $suff_len < $suff );
    }
    my $pattern = sprintf( ".{0,%d}%s.{0,%d}", $pref_len, $word, $suff_len );
    $edit{$pattern} = { word => $word,
                        repl => $repl,
                        stop => join( '|', @stops ) };
}

for my $pattern ( keys %edit ) {
    while ( $text =~ /($pattern)/g ) {
        my $edited = my $source = $1;
        next if ( $edit{$pattern}{stop} and $edited =~ /(?:$edit{$pattern}{stop})/ );
        $edited =~ s/$edit{$pattern}{word}/$edit{$pattern}{repl}/;
        $text =~ s/\Q$source\E/$edited/;
    }
}
print $text;

__DATA__
score	twenty	fourscore,scored,scores
core	center	encore,coregent,score
centre	center
travelled	traveled
hasn't	has not
Johann	John	Johannesburg