Re: Installing a module that is perl-version specific

[ikegami]

You could have a front end (interface) that loads the appropriate back end (work horse) based on $].

BEGIN {
   my $backend;
   if    ($] >= 5.010) { $backend = 'Data::Manip::Perl5010'; }
   elsif ($] >= 5.008) { $backend = 'Data::Manip::Perl5008'; }
   elsif ($] >= 5.006) { $backend = 'Data::Manip::Perl5006'; }
   else { die("Perl $] isn't supported\n"); }
   eval "require $backend" or die $@;
   our @ISA = $backend;
}

[ Oops, Date::Manip is a procedural module, so you'll have to use AUTOLOAD or use package Date::Manip; in each of the helper modules instead of using @ISA. ]

[chuckbutler]

Building on the submission by ikegami:

package Date::Manip;
use warnings;
use strict;
use Carp;
use Exporter;
#
  our @ISA;
  our @EXPORT;
  my $backend;
  if    ($] >= 5.010) { $backend = 'Date::Manip::Perl5010'; }
  elsif ($] >= 5.008) { $backend = 'Date::Manip::Perl5008'; }
  elsif ($] >= 5.006) { $backend = 'Date::Manip::Perl5006'; }
  else { croak("Perl $] isn't supported\n"); }
  my $backend_exp = $backend . "::EXPORT";
  eval "require  $backend; $backend->import(); return 1;" or croak "$@
+";
  { no strict qq{refs};
    @EXPORT = @{$backend_exp};
  }
  
  unshift (@ISA, $backend);
#

1;

We pick the correct version of the module to use. Then load the module file and import the symbols dynamically, with an eval. Then we setup the @EXPORT list so it is available when the ->import() subroutine runs as part of use, the symbols are imported into Main::.

Update and Postscript:

If the package statement in the per-version Date::Manip's are left as-is, the following code is preferred:

package Date::Manip;
use warnings;
use strict;
use Carp;
use Exporter;
#
  my $backend;
  if    ($] >= 5.010) { $backend = 'Date::Manip::Perl5010'; }
  elsif ($] >= 5.008) { $backend = 'Date::Manip::Perl5008'; }
  elsif ($] >= 5.006) { $backend = 'Date::Manip::Perl5006'; }
  else { croak("Perl $] isn't supported\n"); }
  eval "require  $backend; " or croak "$@";
#

1;

This should work well.

Good luck. -c