Re: Hash of Regex

[zwon]

in reply to Hash of Regex

Try to check content of the hash:

use strict;

my $test = 'The brown fox int(10) over float(200) fence.';

my %dict = (
    'brown'      => 'yellow',
    /int(\d+)/   => 'int',
    /float(\d+)/ => 'float',
);

use Data::Dumper;
warn Dumper \%dict;
__END__
$VAR1 = {
          'int' => 'float',
          'brown' => 'yellow'
        };

And if you'd use warnings...

Perhaps you also will be interested in:

my %dict = (
    'brown'      => 'yellow',
    qr/int(\d+)/   => 'int',
    qr/float(\d+)/ => 'float',
);

Update: And what you actually want, if I got you right, is:

use strict;

my $test = 'The brown fox int(10) over float(200) fence.';

my %dict = (
    'brown'      => 'yellow',
    'int\(\d+\)'   => 'int',
    'float\(\d+\)' => 'float',
);

for my $i ( keys %dict ) {
    $test =~ s/$i/$dict{$i}/gi;
}

print "$test\n";

[almut]

$VAR1 = {
          'int' => 'float',
          'brown' => 'yellow'
        };

(note to the OP)  In case you wonder why this is:

my %dict = ( 'brown'      => 'yellow',
             /int(\d+)/   => 'int',
             /float(\d+)/ => 'float',
           );

is the same as

my %dict = ( 'brown'      => 'yellow',
             $_ =~ /int(\d+)/   => 'int',
             $_ =~ /float(\d+)/ => 'float',
           );

which (in this case) is the same as

my %dict = ( 'brown'      => 'yellow',
             () => 'int',
             () => 'float',
           );

which is the same as

my %dict = ( 'brown'      => 'yellow',
             'int' => 'float',
           );

[Anonymous Monk]

Why / how did this

my %dict = ( 'brown'      => 'yellow',
             () => 'int',
             () => 'float',
           );

become this??

my %dict = ( 'brown'      => 'yellow',
             'int' => 'float',
           );

[LanX]

For Perl => is just a comma, and empty lists () are ignored when flattening lists.

perl -e' @a=(1,2,(),(),3);print "@a"'
1 2 3

[almut]

Empty elements (lists) in a list collapse,  e.g. (1, (), 2, 3, (), (), 4) is the same as (1, 2, 3, 4).

[7stud]

Perhaps you also will be interested in:</p.

my %dict = (
    'brown'      => 'yellow',
    qr/int(\d+)/   => 'int',
    qr/float(\d+)/ => 'float',
);

That doesn't do anything for me.
Edit: Woohoo. More negative rep. Keep it coming. I'm shooting for -100,000 by next week.

[zwon]

That doesn't do anything for me.

That shouldn't. OP asked if he can use regexp as a hash key, so I think he may be interested in inspecting content of mentioned hash with the help of Data::Dumper

[bichonfrise74]

Thanks, I should have first checked the content of my hash using Data::Dumper.

[Anonymous Monk]

my %dict = (
    'brown'      => 'yellow',
    qr/int(\d+)/   => 'int',
    qr/float(\d+)/ => 'float',
);

This is the output, but what does it mean and why doesn't it work?

$VAR1 = {
          '(?-xism:int(\\d+))' => 'int',
          'brown' => 'yellow',
          '(?-xism:float(\\d+))' => 'float'
        };

This looks more elegant than this.

my %dict = (
    'brown'      => 'yellow',
    'int\(\d+\)'   => 'int',
    'float\(\d+\)' => 'float',
);

[crashtest]

Only strings can be hash keys. So when building %dict with regular expressions (the qr// constructs), they are converted to strings to become keys in the hash¹. For regular expressions, incidentally, these are strings that can be compiled back into the same regular expression they stemmed from - which is quite convenient.

So why did this not do anything to bichonfrisee74's input strings?

my %dict = (
    'brown'      => 'yellow',
    qr/int(\d+)/   => 'int',
    qr/float(\d+)/ => 'float',
);

I was scratching my head myself until I use'd re 'debug'. zwon happened to forget to escape the parentheses in his (intermediary) example. So if you use the (correctly written) qr// constructs below, things "work" as expected:

my %dict = (
    'brown'      => 'yellow',
    qr/int\(\d+\)/   => 'int',
    qr/float\(\d+\)/ => 'float',
);

---

¹The ?-xism used to confuse me until I realized this just explicitly states: turn off the x, i, s and m regex flags.