my $confpath;
my $servername;
my $filepath;
my $filemaxage;

$confpath = "/export/mksysb";
$filepath = "/export/mksysb";
$filemaxage = "360";
[download]

The usual practice is to define and initialize variables in the same step:

my $confpath   = '/export/mksysb';
my $filepath   = '/export/mksysb';
my $filemaxage = 360;
[download]

By the way, $confpath and $filepath have the same value so is there really a need for two variables?

while(<FILE>){
    chomp($servername = $_);
[download]

That is usually written as:

while ( my $servername = <FILE> ) {
    chomp $servername;

[download]

        if (-M $_ > "$filemaxage"){
[download]

You are converting $filemaxage to a string and then Perl has to convert it back to a number in order to do a numerical comparison.

What's wrong with always quoting "$vars"?

        mkdir("$filepath/$servername");

system("nim -o define -t mksysb -a server=master -a mk_image=yes -a lo
+cation=$filepath/$servername/$servername\_`date +%m%d%Y` -a source=$s
+ervername $servername\_`date +%m%d%Y`");
[download]

You should also check for failure with mkdir and system like you already do with open and unlink.

Useless interpolation of literal string at line 22, column 13.
Bareword file handle opened at line 26, column 1.
Glob written as <...> at line 36, column 10.  See page 167 of PBP.
Readline inside "for" loop at line 36, column 10.  See page 211 of PBP
+.
[download]

You can also convert your comments to POD and get a manpage for free:

=head1

PURPOSE: Create an mksysb of servers listed in $path\mksysb.conf.
          Also, purge all mksysb's that are over an age set by the 
          filemaxage parameter.  

=cut
[download]

... then from the command line:

perldoc mksysb.pl
[download]

Right ++! The template that I use for starting all my perl source files is something like this, which is pretty much what you see in most CPAN modules:

#!/usr/bin/perl

=head1 NAME

=head1 SYNOPSIS

=head1 DESCRIPTION

=cut

use strict;

[download]

I normally fill in the POD sections before I write any actual code. (This helps me establish and maintain focus, which tends to make the code easier and quicker to write.)

use POSIX;

...
    my $datedname = join('_', $servername, strftime("%m%d%Y", localtim
+e());
    my %opts = (
        server => 'master',
        mk_image => 'yes',
        source => $servername,
        location => "$filepath/$servername/$datedname",
        );

    my @cmd = qw/nim -o define -t mksysb/;
    for my $o ( keys %opts ) { push @cmd, '-a', "$o=$opts{$o}" }
    push @cmd, $datedname;
    print " command-line:  @cmd\n";
    system( @cmd );
}
[download]

(updated code snippet to add a missing quotation mark)

All good comments so far but you should also use lexical filehandles instead of barewords:

open(FILE, '<', "$confpath/mksysbmachinelist.conf") or die $!;
while(<FILE>){
...
[download]

open( my $fh, '<', "$confpath/mksysbmachinelist.conf" ) or die $!;
while( my $line = <$fh> ) {
...
[download]

The reasons for preferring lexical filehandles instead of bareword are

• barewords are really package variables and those have their own issues
• if another file is all ready open under that package variable, it will be closed.
• if you also have a subroutine named the same, your code will fail silently.

Lexical filehandles have been around since perl 5.6 (2000) but it's only recently (perl 5.8.9) that the perldoc has been updated to reflect that lexicals are really the way to go.