How do you list all files under a directory?

[daverave]

I usually use something like

    my $dir="/path/to/dir";
    opendir(DIR, $dir) or die "can't open $dir: $!";
    my @files = readdir DIR;
    closedir DIR;

or sometimes I use glob, but anyway, I always need to add a line or two to filter out . and .. which is quite annoying.

How do you usually go about this common task?

[Corion]

Use File::Glob::bsd_glob:

use File::Glob qw(bsd_glob);
my @files = bsd_glob "$dir/*";

[toolic]

The File::Slurp::read_dir solution from the cross-posted question is a clean solution.

[superfrink]

Here is some code to find emacs ~ files and delete them.


#!/usr/bin/perl -w

use strict;
use File::Finder;
use Data::Dumper;

# list of dirs to look in
my @start_dirs = (
    '/home/chad/' ,
);

my $finder = File::Finder

    # do not go into the ~chad/Archives/ directory.
    ->type('d')->name('Archives')->prune->comma

    # match the following properties.
    ->type('f')      # files
    ->name('*~')     # named glob(*~)
    ->ctime('+6')    # inode changed time more than 6 days ago
#    ->ls()           # print `ls -l` of file
;

# run the finder command now.
my @file_list = $finder->in(@start_dirs);

# delete the found files.
my $count = unlink @file_list;
print "\nUnlinked $count files.\n";

exit(0);

[perl-diddler]

For looking for all the files with a given extension, I used:

 my @uwavs = grep {/^(.*?$SrcExt)$/ && -f $_ } readdir $dirhandle;

To exclude dot files, I'd probably use something like /^([^\.]+.*)$/ for my regex. Obviously in my case, I also only wanted files, so you might not need the "-f $_" part.

As usual, there's always a bunch of ways to do things.

[Proclus]

My favorite IO module is IO::All


    #Read all the files/directories in a directory:
    $io = io('my/directory/');   # Create new directory object
    @contents = $io->all;       # Get all contents of dir

[Marshall]

This glob stuff can get hairy as there are multiple versions of it. I've had some big troubles in the past with this in the Windows environment. Adding a grep to process the list from readdir is portable and is just a few more characters to your standard "formula".

Technically a directory is a file, but -f means the subset of files that aren't directories (which excludes '.' and '..'). Be sure to use a full path name in the grep otherwise you will be testing against files in the directory that the program is executing in, which is probably not what you want! When I do want that, I set $dir = "." and use the same formula.

my $dir="/path/to/dir";
opendir(DIR, $dir) or die "can't open $dir: $!";
my @files = grep {-f "$dir/$_"} readdir DIR;
closedir DIR;

Updated: added single quotes to make '.' and '..' more clear in some fonts.

[dasgar]

I usually cheat by calling the 'ls' or 'dir' command (depending on OS) with the appropriate options inside of backticks. Since I primarily work in Windows, sometimes I'll bust out the Win32::File module to test the returns of readdir to determine what's a file and what's a directory.

Instincts tell me that there's probably a 'better' way to do it, but I haven't found it yet and have been too impatient to look for it when I needed to do something like this.