It's your choice, but you don't really need a module for this. The simplest way might just be to match the first three numbers, then do a ">= and <=" on the range in the last one.

A slightly more elegant method exploits the fact that IPv4 address are actually 4 byte values -- notice each number ranges from 0-255 (an unsigned, one byte char). If you pack them in order you have a "big endian" (aka. network byte order) number, which is actually how low level networking uses them. Making this easy:

#!/usr/bin/perl -w
use strict;

sub dot2int {
    my $address = pop;
    my @bytes;
    while ($address =~ /(\d+)/g) {
        push @bytes,$1
    }
    return unpack('N',pack('C*',@bytes));
}

my $first = dot2int('192.168.1.120');
my $last = dot2int('192.168.1.141');

my @testcases = qw(
    192.168.1.130 
    193.168.1.122 
    255.0.0.27 
    192.168.1.127 
    192.168.1.144 
    192.168.1.139
);

print "$first to $last = ".
    ($last-$first)." addresses in range\n";

foreach (@testcases) {
    print $_;
    my $int = dot2int($_);
    if ($int >= $first && $int <= $last) {
        print " spammer!!!\n";
    } else { print " OK.\n" }
}          
[download]

The output:

3232235896 to 3232235917 = 21 addresses in range
192.168.1.130 spammer!!!
193.168.1.122 OK.
255.0.0.27 OK.
192.168.1.127 spammer!!!
192.168.1.144 OK.
192.168.1.139 spammer!!!

I would assume there is a module somewhere that includes a function like that, but I can't tell you which one.

By the way,

    my @bytes;
    while ($address =~ /(\d+)/g) {
        push @bytes,$1
    }
[download]

can be written as

    my @bytes = $address =~ /(\d+)/g;
[download]

so you end up with

unpack('N', pack('C*', $address =~ /(\d+)/g))
[download]

It's your choice, but you don't really need a module for this. The simplest way might just be to match the first three numbers, then do a ">= and <=" on the range in the last one.

While that would work for the example given, it wouldn't work if he needed to see if an address was in the range 192.168.0.0 - 192.168.1.255.

Works like a charm, finally wound up using most of your example above. many thanks!

Alex

Not sure on how you're judging suckage, but Net::Netmask includes the helper function range2cidrlist that will turn an arbitrary range into an equivalent array of CIDRs (actually, Net::Netmask objects):-

my $is_in_range = grep $_->match($ip_x),
  range2cidrlist($ip_range_start, $ip_range_end);
[download]

(match is a Net::Netmask method.)

Thanks for tip on CIDR.

Not sure on how you're judging suckage, but...

Interesting you highlighted that part of my post. I know that criticism is not very popular, so shoot me me. Maybe it's just me but it's my impression that the "IP" related modules need some revision/cleanup, at least when compared to other similar parts of the CPAN (example: HTTP:x modules). Again, it may very well be an incorrect perception but in these IP modules I noticed: namespace scattering/pollution on all the "IP", "NetAddr", "Net", etc... is really confusing. Several modules seemed to do the same thing, a lot of wheel re-invention IMO, some are poorly or carelessly documented, and several other things.

$ perl -MNet::CIDR -e '
  print Net::CIDR::cidrlookup(
    "192.168.1.130",
    Net::CIDR::range2cidr("192.168.1.120-192.168.1.141")
  )'
1
$ perl -MNet::CIDR -e '
  print Net::CIDR::cidrlookup(
    "192.168.1.180",
    Net::CIDR::range2cidr("192.168.1.120-192.168.1.141")
  )'
0
[download]