filehandle regex

[pinnacle]

Question

I am trying to print line above the the regex in below program in if statement in the file. I am using $` but it does not display any output. I checked my syntax which is correct. Please assist

#!/usr/bin/perl

use strict;

open(ORA, "/usr/cle_un");

while(<ORA>){

print "test: $`\n" if /^Func_file_permission$/;

}
close(ORA);

File details

ram: 702
Func: Func_file_permission
testing

tam: 768
Func: Func_file_permission
test

cham: 803
Func: Func_file_permission
test

I want my results to show:

ram: 702
tam: 768
cham:803

[ikegami]

I am using $` but it does not display any output.

There's nothing before /^/ in the matched variable, so there's nothing in $`.

The solution is to stop overwriting the value you want.

my $prev;
while (<>) {
   print($prev) if /^Func_file_permission$/;
   $prev = $_;
}

[jwkrahn]

$ echo "
ram: 702
Func: Func_file_permission
testing

tam: 768
Func: Func_file_permission
test

cham: 803
Func: Func_file_permission
test
" | perl -e'
local $/ = "";
while ( <> ) {
    print /\A(.*\n)/ if /Func_file_permission$/m;
    }
'
ram: 702
tam: 768
cham: 803

[7stud]

Also learn to open() a file correctly:

open my $INFILE, '<', 'filename'
    or die "Couldn't open file: $!";

while (my $line = <$INFILE>) { ...

[JavaFan]

To print the previous line, one way of doing it is:

my $prev = "";
while (<ORA>) {
    print $prev if /^Func_file_permission$/;
    $prev = $_;
}

[pinnacle]

Thanks for the solution it works!! One thing I don't understand why we are using my $prev = ""; also $prev = $_; due to which I am getting previous line from the file

What's the magic behind it

Thanks!!

[CountZero]

Yes, it will also work, but then the script will not run under use strict;.

[JavaFan]

The my $prev part is there to properly declare the variable. The = "" is there to not have warnings if the first line actually matches. The ; is there to separate statements.

[CountZero]

If you are sure the data you want is always on the first line of each block, you could try this:

use Modern::Perl;

{
    local $/ = '';
    say +(split /\n/)[0] while <DATA>;
}

__DATA__
ram: 702
Func: Func_file_permission
testing

tam: 768
Func: Func_file_permission
test

cham: 803
Func: Func_file_permission
test

[aquarium]

instead of using the following static text line as an anchor..why not use a regex to match what looks like a pattern...e.g. /^[a-z]+:\s[0-9]+$/