Re: Regex question - negatives

[moritz]

Can someone suggest to me what I'm doing wrong?

The .+ looks wrong, since it can match [[ and ]] too. You should use [^\]]+ in the first place.

Update: Here's a working regex:

\[\[([^\]]+)]]

But it stops at a single ]. To prevent that, you need a negative look-ahead:

\[\[((?:(?!\]\]).)+)]]

Now that's quite unreadable, so here in detail:

\[\[            # opening delimiter
(               # capture...
  (?:           # a group
    (?!\]\])    #    that does not start with ]]
    .           #    and is a single character long
  )+            # and many of these groups, at least one.
)
]]              # closing delimiter

[JavaFan]

To prevent that, you need a negative look-ahead:

No, you don't.

$_ = "[[foo]] bar [[baz ] qux]] [quux]] fred [[waldo]]]";
say $1 while /\[\[([^]]*(?:\][^]]+)*)\]\]/g;
__END__
foo
baz ] qux
waldo

This uses some classical loop-unrolling, and is, IIRC, similar how Mastering Regular Expressions (first edition) matches C comments.

[ultranerds]

Hi,

Aaah ok - so I was calling it AFTER, which basically meant that it wasn't matching the string at the point I was expecting :) Thanks for that!

This works fine now:

$test =~ s{\[\[([^\]]+)\]}{
print "FOO: $1 \n";    
}ge;

Thanks again!

Andy

[ultranerds]

Hi,

Thanks - just having a look into those negative look-ahead stuff, as I'm sure that will be good to know for other regexes.

You example doesn't seem to work?

\[\[            # opening delimiter
(               # capture...
  (?:           # a group
    (?!\]\])    #    that does not start with ]]
    .           #    and is a single character long
  )+            # and many of these groups, at least one.
)
]]              # closing delimiter

"Substitution replacment not terminated at line24"

any ideas?

TIA

Andy

[ELISHEVA]

moritz's example is meant to be used with the x modifier which permits comments in a regex. For example:

my $re= qr{\[\[            # opening delimiter
(               # capture...
  (?:           # a group
    (?!\]\])    #    that does not start with ]]
    .           #    and is a single character long
  )+            # and many of these groups, at least one.
)
]]              # closing delimiter
}x;

while ($test =~ m{$re}g) {
  print "FOO:<$1>\n";
}

[ultranerds]

Hi,

Ah cool, didn't know about that feature either =)

Seems it doesn't wanna work with a s/// though?

This works fine, and prints out all the tag I expected:

while ($test =~ m{$re}g) {
   print "FOO:<$1>\n";
}

..while this only prints out the "test new line" one for some reason?

$test =~ s{$re}{
    print "BLA: $1 \n";
}ge

EDIT, never mind - me being stupid with my syntax ;)

TIA

Andy