Re: Help Me!

[jwkrahn]

#!/usr/bin/perl

use strict;
use warnings;

Very good start!    These pragmas should be at the beginning of every Perl program.    (Note that it is spelled Perl, not PERL.)

open FILE, "/home/ajb004/Paradigms/roster.txt" or die $!;

You should usually use the three argument form of open and lexically scoped filehandles and you should probably include the file name in the error message so you know which file failed to open.

        $_;

You have a variable in void context which should trigger a warning message.

                $_ = $word;
                s/_/ /g;
                print "ID: $_\n";

Why are you modifying $_ in this loop when you could just use $word directly?

                $word =~ s/_/ /g;
                print "ID: $word\n";

And since you are also using $_ in the outer loop then this could cause problems in some situations so you should probably avoid using $_ if you can:

while ( my $line = <FILE> )
{
        my @words = split /,/, $line;
        foreach my $word ( @words )
        {
                $word =~ s/_/ /g;
                print "ID: $word\n";
        }
}

And if you are modifying single characters then the tr/// operator is usually more efficient than the s///g operator.

According to your explanation and data you probably need something like this:

#!/usr/bin/perl
use strict;
use warnings;


my $file = "/home/ajb004/Paradigms/roster.txt";

open my $FILE, '<', $file or die "Cannot open '$file' because: $!";

while ( my $line = <$FILE> )
{
        chomp $line;
        $line =~ tr/_/ /;
        my ( $id, $name, $major, $email ) = split /,/, $line;
        print <<TEXT;
ID: $id

Name: $name

Major: $major

Email: $email
TEXT
}

[JavaFan]

You should usually use the three argument form of open and lexically scoped filehandles and you should probably include the file name in the error message so you know which file failed to open.

Actually, it's quite common that it doesn't matter whether one uses 2-arg, or 3-arg open. This is one of the cases.

As for the error message, considering the program only tries to open one file, with a fixed name, it should be bloody obvious which file failed to open. "Should include the file name" is a much too strong.

[GrandFather]

The sooner one starts using safety nets like strictures, lexically scoped variables, full error messages and so on the more benefit one derives from their use and the more likely that such techniques will become habit. The time when such techniques are most useful is during the discovery stages of learning the language, not later on when one should know better in any case and has a better debugging toolkit to help sort problems out in any case.

While there is a balance between introducing too much and introducing good habits early, the OP (by accident or design) is already using strictures and checking the success of open, so introducing another related three safety net techniques seems reasonable.