Is there a way to do this with strict enabled?

You can use can to return a coderef:

use strict;
use warnings;

my $doFoo = main->can ('foo');

print $doFoo ? $doFoo->() : "Can't foo\n";

sub foo {
    return 1;
}
[download]

Prints:

1
[download]

True laziness is hard work

Yes, there are ways of fooling strict. It's simpler and clearer to just turn it off in the code in question.

my $func_name = 'f';
my $cr = do { no strict 'refs'; \&$func_name };
say $cr->();
[download]

you can do it using eval to return the coderef, as follows:

use strict;
use warnings;

sub some_sub {
    "hello\n";
}

my $sub_name = 'some_sub';
my $coderef = eval("\\&$sub_name");

print &$coderef();
[download]

... what I would really like is to map a string to the code reference of the function itself ...

If you mean an arbitrary string, the following is one way.

>perl -wMstrict -le
"my %f_map = ( glue => \&foo, );
 ;;
 print $f_map{glue}->('hoo');
 ;;
 sub foo { return 'FOO' . $_[0]; }
"
FOOhoo
[download]

This looks like an XY Problem. What problem are you trying to solve? What alternatives have you considered?

Generally, symbolic references should be avoided, as convincingly demonstrated by MJD in three parts: part 1 and part 2 and part 3.

use strict;
use warnings;

sub func1 {
    print "running func1\n";
}
my %funcs = (
    'func1' => \&func1,
    'func2' => sub {
        print "running func2\n";
    }
);

$funcs{'func1'}->();
$funcs{'func2'}->();
[download]

Am I missing something?

Yes: the fact that the OP wasn't using hashes for storing code references and was hoping to use a symbolic reference for the function call. Reading the previous replies may have made this clear.

True laziness is hard work

I did read them, but apparently it didn't sink in at the time because I couldn't think of a situation where you wouldn't know your function names in advance. The only exception might be if you're taking user input and running the function asked for, which would be inherently unsafe I would think.

Still, valid point. ikegami's solution is obviously what the OP was looking for. I should stop posting after a hard coding session when my brain is already tired.