Re: Please help

[tobyink]

in reply to Please help

Here's how I'd do it...

use Modern::Perl;
say "Enter a word... maybe it's a palindrome...?";
chop(my $input = lc <>);
my $reversed = join q(), reverse split q(), $input;
say $reversed eq $input ? "yeah" : "nah";

... but don't submit that as-is. Learn from it and write your own.

The chop() function I only use once here, to remove the line-break character from the user input. chop not only tells you what the last character was in the string, it also modifies the string! Thus your comparison at the end will never work, because by the time you've chopped $user nine times, it'll be empty.

(Plus comparing an array and a string using "==" doesn't do what you seem to think it will do.)

Here's a version somewhat closer in spirit to your version:

use Modern::Perl;

# Get a line from the user, and remove the
# trailing line break
say "Enter a word...";
chop(my $user = lc <>);

# Keep a copy of the user input because we're
# about to totally destroy $user.
my $original = $user;

# An array that we're going to split the
# input into.
my @userinput;

# Keep going while there's still some input.
while (length $user)
{
    # Chop takes a character from the end
    # of the string. Unshift adds something 
    # to the start of the array. So this
    # reverses the string as it goes!
    
    unshift @userinput, chop $user;
}
# Now join the array back into a string.
my $reversed = join q(), @userinput;

if ($original eq $reversed)
{
    say "PALINDROME";
}
else
{
    say "NOT A PALINDROME";
}

[Happy-the-monk]

tobyink, reverse works on strings, too, so you can save yourself the trouble and drop both split and join

Cheers, Sören

[Not_a_Number]

Your code is broken:

D:\progs\perl>palindrome.pl
Enter a word...
noon
PALINDROME

D:\progs\perl>palindrome.pl
Enter a word...
ipswich
PALINDROME

D:\progs\perl>palindrome.pl
Enter a word...
bolton
PALINDROME

The line

    unshift @userinput, chop $user;

needs to be changed to

    push @userinput, chop $user;

[CountZero]

The chop() function I only use once here, to remove the line-break character from the user input.

As on many systems the EOL code is two characters long, chop will only remove one and leave you with a "broken" string.

Use chomp to remove the EOL code instead.

[tobyink]

chop is not great at all, but it was in the project brief. :-)