my @dna_chunks = ...;
sub your_test {
   my $string = shift;
   # do your test here, and return 1 if it passes
}

my @used = grep your_test($_), @dna_chunks;
my $long_string = join '', @used;
print "Used ", scalar(@used), " chunks, ",@dna_chunks - @used, " disca
+red";
[download]

See grep for details.

The combination of join and grep sounds like it will do what you want. (map and sort and some of their friends from List::Util and List::MoreUtils are also often useful, but don't sound needed in your case.)

The following example uses join and grep to filter the numbers from 1 to 20 for primes, then join the primes together into a string separated by semicolons.

sub is_prime
{
   my $num = shift;
   return if $num == 1;  # 1 is not prime
   
   die "usage: is_prime(NATURAL NUMBER)"
      unless $num =~ /^[1-9][0-9]*$/;
   
   for my $div (2 .. sqrt $num)
   {
      return if $num % $div == 0;
   }
   return 1;
}

my @numbers = 1 .. 20;

print join ";", grep { is_prime($_) } @numbers;
[download]

perl -E'sub Monkey::do{say$_,for@_,do{($monkey=[caller(0)]->[3])=~s{::}{ }and$monkey}}"Monkey say"->Monkey::do'

It sounds like you need something like this:

my ( $fasta, $valid, $invalid );
while ( <STDIN> ) {
    tr/ATCGatcg//cd;
    next unless /[ATCGatcg]/;
    if ( length % 3 ) {
        $invalid++;
        next;
        }
    $valid++;
    $fasta .= $_;
    }

print LOGFILE "Found ", $valid + $invalid, " blocks, joined $valid of 
+them and left out $invalid.\n";

[download]

>perl -wMstrict -le
"use List::MoreUtils qw(part);
 ;;
 my @strings = qw(X XY  AAA  WXYZ VWXYZ  BBBCCC  TUVWXYZ);
 ;;
 use constant {
   X3  => 0,
   NX3 => 1,
   };
 my @indices =
   part { length($strings[$_]) % 3 ? NX3 : X3 } 0 .. $#strings;
 ;;
 print qq{indices of strings whose lengths are...};
 print qq{ even multiples of 3: @{$indices[X3]}};
 print qq{ non-even multiples of 3: @{$indices[NX3]}};
 ;;
 my $aminos = join '', @strings[ @{$indices[X3]} ];
 print qq{amino acids: '$aminos'};
"
indices of strings whose lengths are...
 even multiples of 3: 2 5
 non-even multiples of 3: 0 1 3 4 6
amino acids: 'AAABBBCCC'
[download]

From the OP:

... Found x blocks (x = number of elemens in the array = $#array) ...

$#array is the highest index of an element in the array. The number of elements would be given by  scalar(@array) or, in general, by evaluating  @array in scalar context, e.g.,  0+@array or  @array == 3 or some such.

#!/usr/bin/perl
use strict;
use warnings;
use Bio::SeqIO;

my $in  = Bio::SeqIO->new( -file   => "input1.txt" ,
                           -format => 'fasta');
my ($string, $valid, $invalid) = ('', 0, 0);
while ( my $seq = $in->next_seq() ) {
    if ($seq->length % 3 == 0) {
        $string .= $seq->seq;
        ++$valid;
    }
    else {
        ++$invalid;    
    }
}

open LOGFILE, ">", 'somefile' or die "Unable to open 'somefile' for wr
+iting. $!";
print LOGFILE "Found ", $valid + $invalid, " blocks, joined $valid of 
+them and left out $invalid.\n";
close LOGFILE or die $!;
[download]

Chris

Hi again! Thank you very much for all of your help and really good ideas. I will try all of them and see which works best in my programm. Christoforo, you're completely right: the input file is an annotated fasta file, which I have to read line by line and analyse for Codon Usage and so on. I didn't use Bioperl for creating a seqobject but instead did all the work by myself. :-) Your wellthought objection can be clearly answered, I think. If all parts are divisible by three the entire sequenz should be also divisible by three, because it consists of parts which are divisible by three. Thanks again, Markus