What does your current attempt look like, and how is it failing to meet your specification?

I have updated with with some code. I can identify the lines but the number of fields per line can vary.

Cut fields 0-7 and cut fields $NF - -8. What remains is the file name with spaces. The number of fields left to print could be varied, 1 fields, 2 fields, ...

Thanks

Show some examples of what you are trying to parse and the expected result.
Make this a simple as possible.
If for example, the first 7 fields don't matter, don't show them.
If you have some Perl code, show it.

I have updated with with some code. I can identify the lines but the number of fields per line can vary.

Cut fields 0-7 and cut fields $NF - -8. What remains is the file name with spaces. The number of fields left to print could be varied, 1 field, 2 fields, ...

Thanks

Ok, you have some code now which is a start. However, in general showing some code that "doesn't work" is not that useful unless you also include the actual input, actual output and DESIRED output of that code.

The best is if I have a runnable code example to see exactly what it does given the input. Then some explanation of what you want it to do.

Showing the DATA is important.
Show some examples of these various types of lines - It is possible that I will code it very differently than your formulation.

If there are X fields at the beginning of some huge line, maybe you don't have so show all of them - maybe just one of the first 8-9 fields here would be sufficient? Show one example of the "whole thing", then the simplified examples where the variations start.

As davido and Marshall have pointed out, it would be nice to see some code, even a very bare beginning.

However, a few hints and suggestions:

• One might be tempted to extract the filename with a regex, but the use of split might be more direct if less elegant. One problem with split is that the fields matching the splitting regex are typically lost, so if you split on multiple spaces and the file name has multiple spaces between file name sub-fields such as
      my $string = 'aa bbb a  file   name cc ddd';
  this information is lost. This can be avoided by enclosing the split regex in capturing parentheses, which preserves fields matching the splitting regex, so
      my @fields = split /(\s+)/, $string;
  and everything can be joined back together again later.
• Take a look at splice. This built-in will chop n elements off the end of an array such as might be produced by split (and return them, but you don't have to use them) if given a negative offset -n, and delete and return all elements from offset n to the end of an array if given a positive offset. You seem to know the constant field offsets from the start and end of the original string.
• Last but not least, join, your constant companion.

Thanks. I will look into splice.

Can you use something like Net::SFTP instead? It can give you a list of filenames as a list, so you don't have to go parsing the lines yourself. It looks like it's been stable since before 5.8.8

Thanks. I will look into Net::SFTP. It may not be work in this specific application but I do have an SFTP site that will need parsing as well.

As long as you have a constant number of fields and the only field that can contain spaces is your filename one, the problem can be solved using the third argument to split combined with reverse.

knoppix@Microknoppix:~$ perl -Mstrict -Mwarnings -E '
> my @lines = (
>    q{1 2 3 4 5 6 7 8 filename 10 11 12 13 14 15 16 17 18},
>    q{1 2 3 4 5 6 7 8 file name 10 11 12 13 14 15 16 17 18},
>    q{1 2 3 4 5 6 7 8 new file name 10 11 12 13 14 15 16 17 18},
>    );
> 
> foreach my $line ( @lines )
> {
>     my @flds = split m{\s+}, $line, 9;
>     @flds    = split m{\s+}, reverse( $flds[ -1 ] ), 10;
>     my $filename = reverse $flds[ -1 ];
>     say qq{>$filename<};
> }'
>filename<
>file name<
>new file name<
knoppix@Microknoppix:~$ 
[download]

I hope this is helpful.

Thanks John. I have been thinking about reverse. Hoping to see if there is something better.

At first glance this seemed unnecessarily complicated but then I thought, "No, it couldn't be doing that!" So I tried...

#!/usr/bin/perl
use Modern::Perl;

my @lines = (
    q{1 2 3 4 5 6 7 8 filename      10 11 12 13 14 15 16 17 18},
    q{1 2 3 4 5 6 7 8 file     name 10 11 12 13 14 15 16 17 18},
    q{1 2 3 4 5 6 7 8 new file name 10 11 12 13 14 15 16 17 18},
    );

foreach my $line ( @lines ) {
    my @flds = split m{\s+}, $line, 9;
       @flds = split m{\s+}, reverse( $flds[ -1 ] ), 10;
    my $filename = reverse $flds[ -1 ];
    say qq{>$filename<};
    }

foreach my $line ( @lines ) {
    my  @flds     = split(' ', $line);
    my  $filename =  join(' ', @flds[8 .. $#flds - 9]);
    say qq{<$filename>};
    }
[download]

Yes, yours preserves multiple spaces in the file name. Thanks for the enlightenment JohnGG!

preserves multiple spaces in the file name

In case others are puzzled let's share the enlightenment and explain what is going on. The reason spaces are preserved is that the file name field is never actually split. First, the line is broken into nine fields.

1 2 3 4 5 6 7 8 file     name 10 11 12 13 14 15 16 17 18
^ ^ ^ ^ ^ ^ ^ ^ ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
[download]

Then the last field from the first split operation is reversed and broken into 10 fields.

81 71 61 51 41 31 21 11 01 eman     elif
^^ ^^ ^^ ^^ ^^ ^^ ^^ ^^ ^^ ^^^^^^^^^^^^^
[download]

Finally the last field from the second split operation is reversed to obtain the file name.

file     name
[download]

Note that spaces in the file name will be preserved but if the file name has leading and/or trailing spaces the method fails as they will be lost.

Cheers,

JohnGG

I feel that a REGEX makes the intent clear. Efficiency should not be an issue.

use strict;
use warnings;
my $string  
    = 'field1 '
    . 'field2 '
    . 'field3 '
    . 'field4 '
    . 'field5 '
    . 'field6 '
    . 'field7 '
    . 'field8 '
    . 'field9 '
    . 'file name here '
    . 'field11 '
    . 'field12 '
    . 'field`3 '
    . 'field14 '
    . 'field15 '
    . 'field16 '
    . 'field17 '
    . 'field18 '
    . 'field19'
    ."\n"
    ;
my $skip_field = qr /[^\s]+\s+/; # Include any non-whitspace character
my $file_field = qr /[\w\s]+/;   # Include word characters and spaces
my ($file_name)
    = $string =~ m/\A$skip_field{9}($file_field)\s$skip_field{9}\z/;

print $file_name, "\n";
[download]