Re: Uer Perl Variable in file

[choroba]

in reply to Uer Perl Variable in txt file

Using a hash instead of variables is safer (no eval needed). Something like this:

#!/usr/bin/perl
use warnings;
use strict;

my %replace = (name => 'Joe',
               fun  => 'a game');

while (<DATA>) {
    for my $key (keys %replace) {
        s/\$$key/$replace{$key}/g;
    }
    print;
}

__DATA__
Hullo $name,
are you ready for $fun?

[moritz]

Or even

#!/usr/bin/perl
use warnings;
use strict;

my %replace = (name => 'Joe',
               fun  => 'a game');
my $search_for = join '|', map quotemeta, keys %replace;
while (<DATA>) {
    s/\$($search_for)/$replace{$1}/g;
    print;
}

I avoid nested loops where possible.

[tinita]

my $search_for = join '|', map quotemeta, keys %replace;
...
s/\$($search_for)/$replace{$1}/g;

Additionally:
when doing things like this and you have two hash keys "foo" and "foobar", either use \b in the regex if possible, or sort the hash keys for length before joining. otherwise $foobar could be replaced with the value of $replace{foo}.
s/\$($search_for)\b/$replace{$1}/g;