Here's an option to consider:

use Modern::Perl;
use File::Slurp qw/read_file write_file/;

my $test     = 'test.txt';
my $test2    = 'test2.txt';
my $activout = 'ActivACNPF.txt';
my @lines;

my %data = map { /(.+)\s+\|\s+(.+)/; $1 => $2 } read_file $test2;

for ( read_file $test ) {
    /(.+)\s+.+=([^\s]+)/;
    push @lines, "$1 $2 $data{$1}\n" if $data{$1};
}

write_file $activout, @lines;
[download]

Output to file:

Q197F8 IIV3-002R PF04947.9
Q91G88 IIV6-006L PF01486.12 PF00319.13
[download]

%data is initialized using the captured data from test2.txt as key/value pairs. Next, the 'keys' and associated 'values' are captured from test.txt, and the completed line is push onto @lines if a matching key is found. Finally, @lines is written to ActivACNPF.txt.

Hope this helps!

Update: Replaced a single-line map with a multi-line for to improve readability.

Thanks so much! It works like a charm. On a side note, how do I remove the decimal place. I tried using (PF.{5}) instead of the (.+) but it would only return the last PF value and nothing else.

Ask yourself what you want to match?

In regular expression dot means any character

You're welcome, jemswira!

To remove the decimal values in the test2.txt data, try changing the following:

my %data = map { /(.+)\s+\|\s+(.+)/; $1 => $2 } read_file $test2;
[download]

to:

my %data = map {s/\.\d+//g; /(.+)\s+\|\s+(.+)/; $1 => $2 } read_file $
+test2;
[download]

New output to file:

Q197F8 IIV3-002R PF04947
Q91G88 IIV6-006L PF01486 PF00319
[download]

The substitution at the beginning of the map block will globally remove a decimal point followed by one or more digits. Since only the test2.txt values (not keys) contain decimal points, this should work.

The script below could do want you want like so:

use warnings;
use strict;

my ( $file1, $file2 ) = @ARGV;

my $matched_word = {};

open my $fh, '<', $file1 or die "can't open file: $!";
while (<$fh>) {
    s/^\s+?|\s+?$//;
    if (m{(.+?)\s+?.+?=(.+?)\s+?.*?$}) {
        push @{ $matched_word->{$1} }, $2;  
    }
}
close $fh or die "can't close file: $!";

open $fh, '<', $file2 or die "can't open file: $!";
while (<$fh>) {
    s/^\s+?|\s+?$//;
    my ( $value1, $value2 ) = split /\s+?\|\s+?/, $_;
    print $value1, " ", @{ $matched_word->{$value1} }, " ", $value2, $
+/
      if exists $matched_word->{$value1};
}
close $fh or die "can't close file: $!";
[download]

OUTPUT
Q197F8 IIV3-002R PF04947.9
Q91G88 IIV6-006L PF01486.12 PF00319.13
[download]

use Modern::Perl;
use Data::Dump qw/dump/;

my %acn_database;
while (<DATA>) {
    last if /END/;
    my ($acn, $orfname) = split /\sORFNames=|\s/;
    $acn_database{$acn} = [$orfname];
}
while (<DATA>) {
    my ($acn, @pf_data) = split /\s\|\s|\s/;
    push @{$acn_database{$acn}}, @pf_data;
}
say dump(\%acn_database);


__DATA__
Q197F8 ORFNames=IIV3-002R
Q197F7 ORFNames=IIV3-003L
Q6GZX2 ORFNames=FV3-003R
Q6GZX1 ORFNames=FV3-004R
Q197F5 ORFNames=IIV3-005L
Q6GZX0 ORFNames=FV3-005R ;PF02393
Q91G88 ORFNames=IIV6-006L ;PF12299;PF04383
Q6GZW9 ORFNames=FV3-006R
END
Q197F8 | PF04947.9
Q91G88 | PF01486.12 PF00319.13
[download]

Note that this will still do the right thing if you have multiple lines in your second file with the same accession numbers: their data will just be added to right array in the hash.