use feature ":5.14";
use warnings FATAL => qw(all);
use strict;
use Data::Dump qw(dump pp);

sub findEmptyDirectories(&@)
 {package FindEmptyDirectories;
  my $R = shift;                          # Processing routine from user followed by file/directory names

  my $d = {};                             # Simulated directory tree
   {for(@_)                               # Load directory tree with each file
     {if (my @c = /([^\/]+)/g)            # Get path components from file name
       {my $f = pop @c unless /\/\Z/;     # Get file name unless directory
        my $c = $d;                       # Start of descent through directory tree
        $c = $c->{dir}{$_} //= {} for @c; # Descend along each path component adding new nodes as necessary
        $c->{file}{$f}++ if defined $f;   # Count files at this level with this name
       }
     }
   }

  sub R($)                                # Descend tree to count files in each directory 
   {my ($d) = @_;                         # Position in directory tree
    $d->{files} += &R($d->{dir}{$_}) for keys %{$d->{dir}}; # Count files below this level
    $d->{files} += keys %{$d->{file}};    # plus files at this level
   }
  R($d);                                  # Count files at each level

  sub r($$$)                              # Descend tree in in-order in order to perform user action on empty directories 
   {my ($R, $d, $p) = @_;                 # User action, directory sub tree, path to sub tree
  
    return $R->(@$p) unless $d->{files};  # No files below this directory so perform user action and return

    &r($R, $d->{dir}{$_}, [@$p, $_]) for sort keys %{$d->{dir}}; # Else process lower levels in directory tree 
   }
  r($R, $d, []);                          # Call user action on directories with no files
 }

findEmptyDirectories {say "/", join("/", @_), "/"} split /\n/, << 'END';
/peter/john/lilly.pdf
/john/peter/jill.pdf
/jimmy/gill/a.txt
/jimmy/gill/johnny/
/wilbur/yankee/
/wilbur/yankee/aaa/bbb/nnn/
/wilbur/yankee/aaa/ccc/nnn/
/wilbur/yankee/aaa/ccc/aaa.txt
/lola/riley/jibmo/txt
/lola/riley/jibmo.txt
/rolly/polly/quebe.lst
END