Non-local return via last()

For $work I'm writing a text-only menu system, and that defines callbacks which are called for specific input.

Now the default behavior is to simply ignore the return value (trust me, it makes sense in my $work context), and exit the menu when the input is empty. However I want to give some callbacks the possibility to exit the menu too.

How? A normal return() doesn't accomplish that, so here is my hack:

use strict;
use warnings;
use 5.010;

my @return_stack;

sub RETURN {
    push @return_stack, [@_];
    no warnings 'exiting';
    last 'UNIQUELABEL';
}


sub menu {
UNIQUELABEL:
    while (1) {
        for (@_) {
            $_->();
        }
    }

    return @{pop @return_stack};
};

say menu
    sub { say 'go on'    },
    sub {
        RETURN menu 
            sub { say 'still here' },
            sub { RETURN 'ended'   },
            sub { 'never called'   },
    },
    sub { 'never called'   },
   ;
__END__
go on
still here
ended
[download]

In my menu system, the inner loop is a bit different, but this captures the idea pretty well IMHO.

The same could be achieved through exceptions.

One thing it doesn't handle well is context: the callback is always called in the same context (here void context), so wantarray isn't useful in the callback.

Perl 6 - the future is here, just unevenly distributed

Comment on Non-local return via last()
Download Code

Re: Non-local return via last()
by tobyink (Prior) on Sep 27, 2012 at 12:37 UTC

Nice. I've been looking for a solution for a while for resolving this disparity:

use 5.010;
use List::Util qw(first);

sub sub1 {
    first { return 1 } @_;
    return 2;
}

sub sub2 {
    grep { return 1 } @_;
    return 2;
}

say sub1(0);
say sub2(0);
[download]

Given that first and grep are conceptually similar, it is counter-intuitive that return inside them means different things. While prototypes help first look like a built-in list operator, they don't help it act like one.

I've played around with Scope::Upper a little to try to come up with a resolution for this, but haven't had any luck so far. (Though as a by-product I managed to come up with returning which is pretty fun.) I wonder if last might provide some kind of solution.

perl -E'sub Monkey::do{say$_,for@_,do{($monkey=[caller(0)]->[3])=~s{::}{ }and$monkey}}"Monkey say"->Monkey::do'

[reply]
[d/l]
[select]


good chemistry is complicated, and a little bit messy -LW
	PerlMonks

Non-local return via last()

The best material for plates (tableware) is: