use strict;
use warnings;
use Data::Dumper;

my @S;
while (<DATA>) {
    push @S, [split];
}
print "-----TRIPLETS-------\n";
print Dumper \@S;

my @new = map { [@{ $_ }[0 .. 1]] } @S;
print Dumper \@new;

__DATA__
b c a
a c d
d e b

[download]

Output:

-----TRIPLETS-------
$VAR1 = [
          [
            'b',
            'c',
            'a'
          ],
          [
            'a',
            'c',
            'd'
          ],
          [
            'd',
            'e',
            'b'
          ]
        ];
$VAR1 = [
          [
            'b',
            'c'
          ],
          [
            'a',
            'c'
          ],
          [
            'd',
            'e'
          ]
        ];

[download]

Ok and how do I read the same (i.e. those first two columns into a hash). this is what I tried.

my %h;
my @a = map { [@{ $_ }[0]] } @S;
my @b = map { [@{ $_ }[1]] } @S;
@h{@a} = @b;
print Dumper(@a);
print Dumper(@b);
print Dumper(%h);
print "or\n";
print Dumper(\%h);
[download]

But the output is wrong

$VAR1 = {
          'ARRAY(0x8411210)' => [
                                  'e'
                                ],
          'ARRAY(0x840d768)' => [
                                  'c'
                                ],
          'ARRAY(0x83f3308)' => [
                                  'c'
                                ]
        };
[download]

Is this what you wanted?

my %h = map { $_->[0] => $_->[1] } @S;
print Dumper(\%h);
[download]

Output:

$VAR1 = {
          'a' => 'c',
          'b' => 'c',
          'd' => 'e'
        };
[download]

Note: Once you put the data into a hash, the original order of the keys is lost. This is the way hashes work.

Hope that helps,

Athanasius <°(((>< contra mundum

In your code above, you are creating @a & @b as arrays of references to (one element) arrays. Perhaps what you intend is something like:

my @a = map { ${ $_ }[0] ] @S;
[download]

TJD

Hi guys, there's one more thing Im stuck with. Suppose I have these points=(a,b,c,d);

Then I want to find the set of triplets induced by these 4 vertices.

For example for above four points the induced triplets should be:

b c a
a c d
[download]

Whereas for vertices=(d,e,a) there isn't any triplet in the data.

On a side note, I just want to point out that the code:

# Find the number of vertices
my @L;

for my $i (0 .. $#S)
{
    for my $j (0 .. $#{$S[$i]})
    {
        push(@L, $S[$i][$j]);
    }
}
[download]

can be simplified down to:

my @L = map { @$_ } @S;
[download]

since it’s just flattening a 2-dimensional list into a 1-dimensional list.

I know only too well how hard it is to switch from thinking in C to thinking in Perl. But persevere, it’s worth the effort!

Hope that helps,

Or to explore the language just a little more:

my @l;

push @l, @$_ for @S;
[download]

to show statement modifiers and that push can push multiple elements at a time.

Update: Fix array name inconsistency.

True laziness is hard work

#!/usr/bin/perl
use strict;
use warnings;

use Text::CSV_XS;
use Data::Dumper;

my $param = {   binary => 1,
        auto_diag => 1,
        sep_char => ' ',
        eol       => $/,
};
my %hash;
my $csv = Text::CSV_XS->new ( $param );
while ( my $row = $csv->getline( *DATA ) )
{
    print "@$row[0,1]\n"; # or whatever.
    $hash{$row->[0]} = $row->[1]; # read into a hash.
}
print Dumper \%hash;

__END__
b c a
a c d
d e b

[download]

$VAR1 = {
          'a' => 'c',
          'b' => 'c',
          'd' => 'e'
        };
[download]