If the order of the arrays makes no difference, it sounds like you are looking for an intersection operator of some sort. Array::Utils might have what you are looking for. I found this by searching metacpan for "union intersect".

Otherwise, a method to find them is pretty straightforward:

• configure a hash for the first array (*)

  @hash1{@array1} = (1)x@array1
  [download]

  This configures a hash %hash1 to have a true value for all values found in @array1. (* - This is probably clearer as $hash1{$_} = 1 for @array1)
• loop through the second array picking out those elements that show up in the first array

  push( @intersection, grep { $hash1{$_} } @array2 );
  [download]

Updates:

1. Added example code
2. Added search example
3. D'oh - quite right Jenda. I have got to stop writing code before my first cup of coffee. :-/

See also How do I compute the difference of two arrays? How do I compute the intersection of two arrays?.

Athanasius <°(((>< contra mundum

There's no reason to work hard to set the values in the hash to ones, leave them undefined and use exists() within the grep{}. Also there is no reason to push the elements into the @intersection, just assign them.

my %hash1;
@hash1{@array1} = ();
my @intersection = grep {exists $hash1{$_} } @array2;
[download]

Jenda
Enoch was right!
Enjoy the last years of Rome.

One option is to use List::Compare:

use strict;
use warnings;
use List::Compare;

my @a = qw(a  b  c);
my @b = qw(b  c  d);

print "\@a = @a\n\@b = @b\n\n";

print '@a AND @b = ', arrayANDCompare( \@a, \@b ), "\n\n";

print '@a OR @b = ', arrayORCompare( \@a, \@b );

sub arrayANDCompare {
    my ( $a, $b ) = @_;
    return List::Compare->new( $a, $b )->get_intersection;
}

sub arrayORCompare {
    my ( $a, $b ) = @_;
    return List::Compare->new( $a, $b )->get_union;
}
[download]

Output:

@a = a b c
@b = b c d

@a AND @b = bc

@a OR @b = abcd
[download]