Update: Oops, misread the question. Clearly not the answer.

Update2: This should do it though :-)

Something like this?

use warnings;
use strict;

my %count;

my $hash = {Grand => { Parent1 => {Child1 => { name => "me",
                                               age => 99 },
                                   Child2 => { name => "you",
                                               age => 42 },
                                   Child3 => { name => "she",
                                               age => 1 }}}};

recurse_or_count($hash->{Grand},"Grand");
sub recurse_or_count {
    my ($cur,$string)=@_;
    for my $elem (keys %$cur) {
        if (ref($cur->{$elem}) eq "HASH") {
            $count{$string}++;
            recurse_or_count ($cur->{$elem},$string."->$elem");
        } else {
            $count{$string}->{$elem}=$cur->{$elem};
        }
    }
}

for my $key (sort keys %count) {
    if (ref($count{$key}) eq "HASH") {
        for my $data (sort keys %{$count{$key}}) {
            print "$key has $data $count{$key}->{$data}\n";
        }
    }else {
        my $child = $count{$key} > 1 ? "children" : "child";
        print "$key has $count{$key} $child\n";
    }
}

__OUTPUT__
Grand has 1 child
Grand->Parent1 has 3 children
Grand->Parent1->Child1 has age 99
Grand->Parent1->Child1 has name me
Grand->Parent1->Child2 has age 42
Grand->Parent1->Child2 has name you
Grand->Parent1->Child3 has age 1
Grand->Parent1->Child3 has name she
[download]

Update3: and if you don't mind the child data being printed out before the child count, here's a more efficient version of that:

use warnings;
use strict;

my %count;

my $hash = {Grand => { Parent1 => {Child1 => { name => "me",
                                               age => 99 },
                                   Child2 => { name => "you",
                                               age => 42 },
                                   Child3 => { name => "she",
                                               age => 1 }}}};

recurse_or_count($hash->{Grand},"Grand");
sub recurse_or_count {
    my ($cur,$string)=@_;
    for my $elem (sort keys %$cur) {
        if (ref($cur->{$elem}) eq "HASH") {
            $count{$string}++;
            recurse_or_count ($cur->{$elem},$string."->$elem");
        } else {
            print "$string has $elem $cur->{$elem}\n";
        }
    }
}

for my $key (sort keys %count) {
        my $child = $count{$key} > 1 ? "children" : "child";
        print "$key has $count{$key} $child\n";
}

__OUTPUT__
Grand->Parent1->Child1 has age 99
Grand->Parent1->Child1 has name me
Grand->Parent1->Child2 has age 42
Grand->Parent1->Child2 has name you
Grand->Parent1->Child3 has age 1
Grand->Parent1->Child3 has name she
Grand has 1 child
Grand->Parent1 has 3 children
[download]