There are two assignment operators, the list assignment operator and the scalar assignment operator. If the LHS of an assignment is some kind of aggregate, the list assignment is used. Otherwise, the scalar assignment is used. The following are considered to be aggregates:

• (...) (any expression in parens)
• @array and @array[...]
• %hash and @hash{...}
• my (...), our (...) and local (...) (state (...) throws an error.)

There are two differences between the operators. The first is the context in which operands are evaluated:

• The scalar assignment evaluates both of its operands in scalar context.
• The list assignment evaluates both of its operands in list context.

The second difference is in what they return:

Note that the right-hand side is used for the list assignment in scalar context.

Finally, here are some examples:

# Array evaluated in scalar context.
my $count = @array;
[download]

# The s/// operates on $copy.
(my $copy = $str) =~ s/\\/\\\\/g;
[download]

# Prints $x.
print($x = $y);
[download]

# Array evaluated in list context.
my @copy = @array;
[download]

# Only dies if f() returns an empty list.
# This does not die if f() returns a
# false scalar like zero or undef.
my ($x) = f() or die;
[download]

my $count = () = f();
[download]

# Prints @x.
print(@x = @y);
[download]

Related topics:

• Perl Idioms Explained - my $count = () = /.../g.

Update: Added examples.
Update: Incorporated JavaFan's additions.
Update: Removed list slices and mentioned state.
Update: One of the examples in the scalar context column did not depend on context. It has been moved to its own column. Also, added short explanations of examples.