use warnings;
use strict;
use Data::Dumper;
use Mail::MboxParser;
use Mail::IMAPClient;

my $base_dir    = ".thunderbird/profile_path/Mail/Local Folders/";
my $base_target = "INBOX";
my $imap_server = "localhost";
my $imap_user   = "username";
my $imap_pass   = "password";

my $parseropts = {
        enable_cache    => 0,
        enable_grep     => 0,
        cache_file_name => 'cache-file',
};

my $skip_deleted = 1;

my $imap = Mail::IMAPClient->new(
                        Server   => $imap_server,
                        User     => $imap_user,
                        Password => $imap_pass,
)       or die "Cannot connect to $imap_server as $imap_user: $@";

parse_dir($base_dir);

sub parse_dir {
	my $dir = shift;
	opendir my $dir_h, $dir
					or die "Unable to opendir $dir: $!\n";
	print "Reading directory $dir\n";


	##Dirty, probably IMAP-server dependent stuff.
	#This stuff is for dovecot.
	my $temp_dir = $dir;
	$temp_dir =~ s!^$base_dir!$base_target!;
	$temp_dir =~ s!\.sbd!!g;
	$temp_dir =~ s!/+!/!g;
	$temp_dir =~ s!\.+!_!g;
	$temp_dir =~ s!^/!!;
	$temp_dir =~ s!/ *!.!g;
	if ($temp_dir ne $base_target) {
		print "================================= Making dir $temp_dir\n";
		$imap->create($temp_dir)
						or warn "(A) unable to create $temp_dir: $@\n";
		$imap->subscribe($temp_dir)
						or warn "(A) subscribe to $temp_dir: $@\n";
		print "\n";
	}
	
	foreach my $directory (grep /\.sbd$/, readdir $dir_h) {
		parse_dir($dir."/".$directory);
	}
	seekdir($dir_h, 0);
	foreach my $mail_file (grep !/^\./, grep !/(\.html|\.sbd|\.msf|\.dat)$/, readdir $dir_h) {
		my $mf = $dir."/".$mail_file;
		print "Going to parse $mf\n";
		my $mb = Mail::MboxParser->new($mf,
																		decode     => 'ALL',
																		parseropts => $parseropts);
	
		my $folder_name = $temp_dir.".".$mail_file;
		$folder_name =~ s!/+!/!g;
		$folder_name =~ s!\.+!_!g;
		$folder_name =~ s!^/!!;
		$folder_name =~ s!/ *!.!g;
		print "================================= Making dir $folder_name\n";
		$imap->create($folder_name)
						or warn "(B) unable to create $folder_name: $@\n";
		$imap->subscribe($folder_name)
						or warn "(B) subscribe to $folder_name: $@\n";
	
		for my $msg ($mb->get_messages) {
			#Skip deleted messages...
			unless($skip_deleted and (hex($msg->header->{"x-mozilla-status"}) & 0x0008)) {
				print "Appending msg " . $msg->header->{subject} . " to $folder_name\n";
				unless($imap->append_string($folder_name, $msg, '\Seen')) {
								warn "Couldn't append " . $msg->header->{subject} . " to $folder_name: $@\n";
								warn "Skipping\n";
								next;
				}
			} else {
				warn "Skipping " . $msg->header->{subject} . " - deleted message\n";
			}
	
		}
	}
	closedir($dir_h);

}