Re: Module to parse output from Unix ps command?

[hdb]

It was easier said than done...

use strict;
use warnings;
use Data::Dumper;

my $command = "ps -f";
my $id = "PID";

my @ps =`$command`;
$ps[0] =~ s/^\s*//;
my @header = split /\s+/, shift @ps;
my ($posid) = grep { $header[$_] eq $id } 0..$#header;
die "$id: No such column!\n" unless defined( $posid );
splice @header, $posid, 1;
my $n = (scalar @header) - 1;

my %psdata;
while( @ps ) {
  my $row = shift @ps;
  $row =~ s/^\s*//;
  my @row = split /\s+/, $row;
  my $this_id = splice @row, $posid, 1;
  @{$psdata{$this_id}}{@header[0..$n-1]} = splice @row, 0, $n;
  $psdata{$this_id}{$header[$n]} = join " ", @row; # inaccurate as it 
+just pastes everything together
}

print Dumper( %psdata );

[Krambambuli]

Using split's third possible argument too instead of just /\s+/, you'd preserve the original spacing of the user command as well (assuming it's always the last column).


Krambambuli
---

[hdb]

Thanks for this comment, I never heard about this third argument. Here is the updated script:

use strict;
use warnings;
use Data::Dumper;

my $command = "ps -f";
my $id = "PID";

my @ps =`$command`;
$ps[0] =~ s/^\s*//;
my @header = split /\s+/, shift @ps;
my ($posid) = grep { $header[$_] eq $id } 0..$#header;
die "$id: No such column!\n" unless defined( $posid );
splice @header, $posid, 1;

my %psdata;
while( @ps ) {
  my $row = shift @ps;
    chomp $row;
  $row =~ s/^\s*//;
  my @row = split /\s+/, $row, $#header+2;
  my $this_id = splice @row, $posid, 1;
  @{$psdata{$this_id}}{@header} = @row;
}

print Dumper( %psdata );