Re^2: SVN::Client subclassing issue

[Anonymous Monk]

Guess I look for another way unless I want to modify Client.pm...which I don't :)

Make your class has-a-SVN::Client not is-a-SVN::Client?

It seems to me that portion of SVN::Client is broken, in that it needs to use

UNIVERSAL::isa($_[$index], 'SVN::Client')

instead of ref/eq

Apparently you can report bugs at http://subversion.apache.org/issue-tracker.html

[tj_thompson]

Make your class has-a-SVN::Client not is-a-SVN::Client?

This is what I had in mind. I was going to subclass initially because I wanted some functions to 'fall through' to the SVN::Client class without having to wrap each one. This should be easy enough to do from another object, but it's not something I've done before.

So assuming my new Foo class is called with a function that is not part of the package, let's say Foo->cat. Foo does not have a cat function, but Foo does have a SVN::Client object. I'd like to pass a call to a function that does not exist in the current package to be handled by the SVN::Client object. What is the proper/elegant way to do this?

[tye]

our $AUTOLOAD;
sub AUTOLOAD {
    my( $self )= shift @_;
    my( $class, $method )= $AUTOLOAD =~ /^(.+)(?:'|::)(.+)$/
        or  die "Invalid method name: $AUTOLOAD";
    return
        if  'DESTROY' eq $method;
    die "Can't call internal method, $method, via ", __PACKAGE__, $/
        if  $method =~ /^_/;
    return $self->{whatever}->$method( @_ );
}

Not so much "proper" or "elegant" but a thrown-together example but also not "improper" nor particularly "inelegant".

[Anonymous Monk]

See AUTOLOAD section of Modern Perl: the free book, and mind the caveats

Assuming hashref has-a 'SVN::Client'

sub AUTOLOAD
{
    my ($name) = our $AUTOLOAD =~ /::(\w+)$/;
    my $method = sub
    {
        my $self = shift;
        return $self->{'SVN::Client'}->$name( @_ );
    }
    no strict 'refs';
    *{ $AUTOLOAD } = $method;
    return $method->( @_ );
}