Re^2: Rewrite Program Using Arrays

[perl.j]

I know it might not make it faster, but it's still a learning experience... Can you tell me how to do it?

[aaron_baugher]

Well, you could get rid of your loop by using map, but my benchmark shows no gain there. Eliminating some intermediate variables does speed things up, though. If you get rid of @words and $word completely, you'll gain some time, regardless of which looping method you use:

#!/usr/bin/env perl
use Modern::Perl;
use Benchmark qw(:all);

# create a line with words and spaces to split on
my $line = '';
$line .= ('a', 'b', 'c', 'd', ' ')[rand(5)] for (1..1000);

cmpthese( 100000, {
        'loop with vars' => \&loopwithvars,
        'loop sans vars' => \&loopsansvars,
        'with map'       => \&withmap,
});

sub loopwithvars {
    my %wordcount;
    my @words = split ' ', $line;
    for my $word (@words){
        $wordcount{$word}++;
    }
}
sub loopsansvars {
    my %wordcount;
    for (split ' ', $line){
        $wordcount{$_}++;
    }
}

sub withmap {
    my %wordcount;
    map { $wordcount{$_}++ } split ' ', $line;
}

###### results ######
                  Rate loop with vars       with map loop sans vars
loop with vars 11338/s             --           -15%           -17%
with map       13369/s            18%             --            -2%
loop sans vars 13624/s            20%             2%             --

[ikegami]

Get rid of a scope, use preinc instead of postinc.

sub ikegami {
    my %wordcount;
    ++$wordcount{$_} for split ' ', $line;
}

                  Rate loop with vars      with map loop sans vars       ikegami
loop with vars  8324/s             --          -19%           -20%          -22%
with map       10241/s            23%            --            -1%           -4%
loop sans vars 10370/s            25%            1%             --           -3%
ikegami        10666/s            28%            4%             3%            --

(Post-increment in void context is optimised to pre-increment, but it's not in void context in "with map".)

[mbethke]

Hm, I suppose you meant something like this:

my @globalarray;
foreach my $filename (@ARGV) {
   open my $fh, '<', $filename or die "$filename: $!";
   my @temparray = <$fh>;
   push @globalarray, @temparray;
   close $fh;
}

Guess you could learn the use of "push", that's about the only thing. It's used to append a scalar or a whole list to the end of an array. "pop" does the opposite and takes one scalar off. shift and unshift work the same, just on the start of the array.