read_dir issue

[snowlight]

I am using Strawberry perl on Win7 (64-bit) and have an issue with read_dir. The simple code:

use strict;
use warnings;
use File::Slurp;

my @files;    # Array of all file names in the folder.

if($ARGV[0])
{
  @files = read_dir($ARGV[0]);
}
else
{
  @files = read_dir(".");
}

for my $file (@files)
{
  print $file;
  if(-f $file)
  {
    print " is a file.\n";
  }
  else
  {
    print " is a dir.\n";
  }
}

The file structure used for test:

file1.txt
filetest.pl
folder -> file2.txt
          file3.txt

Running this on current (working) dir, gives correct output:

file1.txt is a file.
filetest.pl is a file.
folder is a dir.

but when providing folder as argument, the files in it are not recognized as files:

file2.txt is a dir.
file3.txt is a dir.

What am I missing?

[moritz]

You are checking -f $file in the current directory, but $file is a file inside the directory you are reading. So there is no such file, and the -f test returns false, which you interpret as a directory.

[fishmonger]

You could/should add the "prefix" option in the read_dir statement so that the path will be prepended to the filename.

@files = read_dir($ARGV[0], prefix => 1);

EDIT:
I'd probably reduce your code a little, like this:

my $path = $ARGV[0] || '.';
my @files = read_dir($path, prefix => 1);

for my $file (@files) {
    say -f $file ? "$file is a file" : "$file is a dir";
}

[zork42]

BUG: folders can contain things other than files and folders.
I'm pretty sure this is true even in Windows.
eg when I do dir C:\Users, I see <DIR>s, but also <SYMLINKD>s and <JUNCTION>s (Windows Vista)
See file test ops

So you might want to change lines 16-27 in your OP, as indicated by ##### in the following:

for my $file (@files)
{
  print $file;
  if(-f $file)
  {
    print " is a file.\n";
  }

  #else                                #####
  elsif (-d _)                         #####

  {
    print " is a dir.\n";
  }

  else                                 #####
  {                                    #####
    print " is something else.\n";     #####
  }                                    #####

}