m//g in list context

[grain_of_sand]

I am trying to debug my understanding of the matching operator. When invoked with the g modifier in list context, I thought that the return value is a list of all possible matches. If capturing parentheses are used, then the list is the set of all $1, $2, etc captured.

The following bit of Perl:

    #!/bin/perl -w
    $" = '-';
    $string = "a:b c:d";
    @list = ($string =~ m/(\w):(\w)/g);
    print "list=@list\n";
    $string = "a:b:c";
    @list = ($string =~ m/(\w):(\w)/g);
    print "list=@list\n";

prints out:

    list=a-b-c-d
    list=a-b

I understand the first line of output, but it seems to me that the second line of output should really be:

    list=a-b-b-c

This is because the (\w):(\w) can match a:b and also b:c. It appears that the regex engine finds the first match of a:b and then starts the next matching attempt after the b, in which case it cannot find the b:c match. I expected the next matching attempt to start after the a, so that the b:c match would also be found.

I have read the Camel book chapter on this & the perlop man page, but they don't really have a lot to say about this...

grain_of_sand

[dws]

When invoked with the g modifier in list context, I thought that the return value is a list of all possible matches.

"All possible" implies matches that overlap with other matches. This isn't how regexs work. With /g, the search for the next match begins immediately after the prior match.

In your example, applying the regex   m/(\w):(\w)/g to   "a:b:c" matches once ("a:b"). The next search begins at ":c", which doesn't match.

[merlyn]

To get what you want, use:

$" = ", ";
$string = "a:b:c";
@list = ($string =~ m/(?=(\w):(\w))/g);
print "list=@list\n";

The lookahead operator will keep restarting where the previous match left off.

-- Randal L. Schwartz, Perl hacker

[Zaxo]

After the match of 'a:b', pos points to the following colon. The next attempt to match is on ':c'.

After Compline,
Zaxo