Setting defaults in subroutines

[rbi]

Hi, could somebody explain me why || and or have a different behaviour as in the example below ? Thank you very much.

use strict;
use warnings;
use Data::Dumper;

my @array = (1,2,3,4);
my @index = (1,3);

&these(Index=>\@index);

&those(Index=>\@index);

sub these {

    my %args = @_;
    my @index = @{$args{Index}} || ();

    my $dump = Dumper($args{Index});
    print "$dump";

    $dump = Dumper(\@index);
    print "$dump";
}
sub those {

    my %args = @_;
    my @index = @{$args{Index}} or ();

    my $dump = Dumper($args{Index});
    print "$dump";

    $dump = Dumper(\@index);
    print "$dump";
}

[davorg]

You're being burnt by a combination of operator precedence and context.

my @index = @{$args{Index}} || ();

is interpreted as

my @index = (@{$args{Index}} || ());

Then the || operator forces scalar context on @{$args{Index}} which therefore gives the number of elements in the array (which is 2).

On the other hand,

my @index = @{$args{Index}} or ();

is interpreted as

(my @index = @{$args{Index}}) or ();

So the array is evaluated in list context and everything works as expected.

[rbi]

Pretty clear explaination. Thank you very much!

[PerlingTheUK]

The best way to see the precedence is to have a look at the cheat sheet, which shows this. I got confused with this myself a couple a weeks ago.

Hans

[PodMaster]

`perldoc perlop'

C:\>perl -MO=Deparse,-p -e"die $a or $b"
(die($a) or $b);
-e syntax OK

C:\>perl -MO=Deparse,-p -e"die $a || $b"
die(($a || $b));
-e syntax OK

C:\>

[hv]

Further to davorg's explanation, my usual idiom for getting the desired result is to move the default into the dereference:

  my @index = @{ $args{Index} || [] };

This sidesteps the problem of @array || something forcing the array into scalar context, and also permits an undefined value.

Hugo

[hmerrill]

I agree. The best way to clarify your test and sidestep the precedence issue is to use parenthesis to explicitly describe how your test should be evaluated.

[Fletch]

Rather than setting %args from @_ and then adding in defaults, I tend to use something along the lines of:

sub foo {
  my @defaults = ( Index => [],
                                 weeble => "floop", );
  my %args = ( @defaults, @_ );

  for( @{ $args{ Index } } ) {
    ## ...
  }
}

You might also want to check out Params::Validate, which provides checking of parameters and allows you to specify default values where required.