Re: Reference assessment techniques and how they fail

[chromatic]

Note that this technique can't detect a code reference because it would call the referenced sub.

It calls the overloaded sub, which has to return a code reference to execute. If you write defined &$some_object, perl will not call the returned code reference, but the expression will evaluate to true.

[kyle]

Good point, but there's actually another problem I forgot to mention. In a &{}, undef is code.

use strict;
use warnings;

use Test::More 'tests' => 3;

sub is_code {
    no warnings qw( void uninitialized );
    return eval { defined &{$_[0]}; 1 };
}

sub real_sub { die 'real sub called' }
my $sub_ref = sub { die 'sub ref called' };
my $undef;

ok( is_code( \&real_sub ), 'real sub ref is code' );
ok( is_code( $sub_ref   ), 'lexical sub ref is code' );
ok( is_code( $undef     ), 'undef is code' );

This isn't a big deal, I guess. We just have to change is_code to return defined $_[0] && eval { defined &{$_[0]}; 1 };. Still, I'd rather call something that figures out what it is than call it to figure out what it is.

[shmem]

Good point, but there's actually another problem I forgot to mention. In a &{}, undef is code.

That's not true. Why is your eval always returning 1 unless it dies? With

sub is_code {
    no warnings qw( void uninitialized );
    return eval { defined &{$_[0]} };
}

things look more reasonable. If undef were code, it'd be a serious bug.

[kyle]

Ah, you're right. I was thinking of the wrong exception and wrote the wrong test.

use Test::More 'tests' => 5;

sub is_code {
    no warnings qw( void uninitialized );
    return eval { defined &{$_[0]} };
}

sub real_sub { die 'real sub called' }
my $sub_ref = sub { die 'sub ref called' };
my $undef;

ok( is_code( \&real_sub ), 'real sub ref is code' );
ok( is_code( $sub_ref   ), 'lexical sub ref is code' );
ok( ! is_code( $undef   ), 'undef is not code' );
ok( ! is_code( 'string' ), 'string is not code' );
ok( is_code( 'real_sub' ), 'string is code' );

So you still need an extra check in is_code.

sub is_code {
    no warnings qw( void uninitialized );
    return '' ne ref $_[0] && eval { defined &{$_[0]} };
}

That's fairly simple, but I think I still prefer the battery of ref, Scalar::Util::reftype, Scalar::Util::blessed and overload::Method.

Read more... (2 kB)