Re^3: How can I get the results in a text file from counting in a string?

[kennethk]

While I certainly think the code could use dramatic algorithmic improvement, I was attempting to keep the logic as consistent as possible, given the OP's apparent level of familiarity. My actual inclination would be to write it as a single pass, stashing results in a hash, so you could separate the processing and the output. Also reduces duplication of code. But to each their own, premature optimization, and all that jazz.

#!/usr/bin/perl
use 5.014;

# 986041

my $str="BATCATDATEFEAT";

my $output = 'Results.txt';

open(my $fh, '>', $output) or die "Can't open $output, $!";

my %spots;
while ($str =~ /([AT])/ig) {
    push @{$spots{uc $1}}, pos $str;
}

for my $key (keys %spots) {
    my $i = 0;
    for my $pos (@{$spots{$key}}) {
        $i++;
        my $text = "\n $key=$i ends at $pos\n";
        print $text;
        print $fh $text;
    }
}

=head execution:

C:\>type Results.txt

 A=1 ends at 2

 A=2 ends at 5

 A=3 ends at 8

 A=4 ends at 13

 T=1 ends at 3

 T=2 ends at 6

 T=3 ends at 9

 T=4 ends at 14

=cut