#!/usr/bin/winperl
use strict;
use warnings;

use Tk;

our @Keywords = qw(
  print
  sprintf
);

our $Comment = '#|//';

our %Highlights = (
  Keyword  => [qw(red bold)],
  Comment  => [qw(gray italic)],
);

setup_window();

MainLoop;



sub setup_window {
  my $mw = MainWindow->new();
  my $t  = $mw->Scrolled('Text', -font => ['Courier New', 10])->pack();

  $t->tagConfigure('red',  -foreground => 'red');
  $t->tagConfigure('gray', -foreground => 'gray');
  $t->tagConfigure('green', -foreground => 'green');
  $t->tagConfigure('bold', -font => ['Courier New', 10, 'bold']);
  $t->tagConfigure('italic', -font => ['Courier New', 10, 'italic']);

  $t->bind(
    '<KeyRelease>',
    # Automatically prepends $t to called sub's args
    [\&highlight_range, 'insert linestart', 'insert lineend'],
  );

  # Paste events my include more than one line to be highlighted,
  # so we rehighlight the entire text.
  $t->bind(
    '<<Paste>>',
    [\&highlight_range, '1.0', 'end'],
  );

  $t->focus();
}

# Remove all formatting so that updates will unhighlight things properly
sub unhighlight_range {
  my $t     = shift;
  my $start = shift;
  my $end   = shift;

  foreach my $style (keys %Highlights) {
    foreach my $tag (@{$Highlights{$style}}) {
      $t->tagRemove($tag, $start, $end);
    }
  }
}

sub highlight_range {
  my $t     = shift;
  my $start = shift;
  my $end   = shift;

  unhighlight_range($t, $start, $end);

  # Highlight keywords
  foreach my $word (@Keywords) {
    my $word_len = length $word;
    my $next = $start;
    while (my $from = $t->search(-regexp, "\\b\Q$word\E\\b", $next, $end)) {
      $next = "$from + $word_len chars";

      # Search for a comment character on the same line
      my $comment = $t->search(
        -regexp => $Comment,
        "$from linestart" => "$from lineend"
      );

      # If comment found and is before keyword, skip formatting
      unless($comment and $t->compare($comment, '<', $from)) {
        mark_word($t, $from, $next, 'Keyword');
      }
    }
  }

  # Highlight comments
  my $next = $start;
  while (my $from = $t->search(-regexp => $Comment, $next, $end)) {
    $next = "$from lineend";
    mark_word($t, $from, $next, 'Comment');
  }
}

sub mark_word {
  my $text  = shift;
  my $start = shift;
  my $end   = shift;
  my $style = shift;

  return unless exists $Highlights{$style};

  foreach my $tag (@{$Highlights{$style}}) {
    $text->tagAdd($tag, $start, $end);
  }
}