Re^2: Using overload to parse arithmetic terms

in reply to Re: Using overload to parse arithmetic terms
in thread Using overload to parse arithmetic terms

To expand (and generalize) on this a bit, let each type of operation have a precedence. Then as you walk the expression tree, you need to parenthesize operations that have a lower precedence than the expression they appear within.

A good way to do this is via OO, representing your operation types as subclasses:

package Op;
sub new {
    my $pkg = shift;
    bless [@_], $pkg;
}
sub children { @{ $_[0] } }
sub display {
    my ($self, $precedence) = @_;
    $precedence = 0 if not defined $precedence;
    my $s = join $self->op,
            map { $_->display($self->precedence) } $self->children;
    $s = "($s)" if $precedence > $self->precedence;
    return $s;
}

package Op::Addition;
@ISA = qw[Op];
sub precedence { 10 }
sub op { " + " }

package Op::Multiplication;
@ISA = qw[Op];
sub precedence { 20 }
sub op { " * " }

# ...

package Op::Term;
@ISA = qw[Op];
sub precedence { 100 }
sub display { $_[0][0] }
[download]

Then you just call the display method on an Op tree. For example,

Op::Multiplication->new(
  Op::Term->new(5),
  Op::Addition->new(
    Op::Term->new(6),
    Op::Term->new(7)
  )
)->display;
# 5 * (6 + 7)

Op::Addition->new(
  Op::Term->new(5),
  Op::Multiplication->new(
    Op::Term->new(6),
    Op::Term->new(7)
  )
)->display;
# 5 + 6 * 7
[download]

And you can see how easy it would be to add new types of operations, due to the beauty of subclassing.

blokhead

Comment on Re^2: Using overload to parse arithmetic terms Select or Download Code

Replies are listed 'Best First'.
Re^3: Using overload to parse arithmetic terms by japhy (Canon) on Feb 07, 2006 at 15:38 UTC
That is a beautiful approach and technique. ++ well deserved. Jeff `japhy` Pinyan, P.L., P.M., P.O.D, X.S.: Perl, regex, and `perl` hacker How can we ever be the sold short or the cheated, we who for every service have long ago been overpaid? ~~ Meister Eckhart	[reply]
Re^3: Using overload to parse arithmetic terms by esskar (Deacon) on Feb 07, 2006 at 16:07 UTC
perfect ... thanks.	[reply]

In Section Seekers of Perl Wisdom