Re: My first perl script is working, what did I do wrong?

[toolic]

If your part numbers will never have spaces in them, you could split your lines and build up a hash of arrays:

use strict;
use warnings;

print "ARGV: $#ARGV\n";

if ($#ARGV != 0) {
     print "One, and only one (not $#ARGV), command line parameter is 
+expected\n";
     exit;
}
my $inputFile=$ARGV[0];

if ( not -e $inputFile) {
     die "$inputFile doesn't exist!!!\nExiting.\n";
}

print "Attempting to open $inputFile\n";

open my $file, $inputFile or die "Could not open $inputFile: $!";

my %parts;
while (<$file>) {
    next if /^Part/;
    my ($part, $info) = split /\s+/, $_, 2;
    $info =~ s/\s//g;
    push @{ $parts{$info} }, $part;
}

for my $info (sort keys %parts) {
    print "@{ $parts{$info} } - $info - ", scalar @{ $parts{$info} }, 
+"\n";
}

__END__

ARGV: 0
Attempting to open 1.txt
P10 - CircleBlue4 - 1
P9 - CircleGreen3 - 1
P1 P4 - CircleRed1 - 2
P7 - RectangleBlue4 - 1
P3 - RectangleRed4 - 1
P5 - SquareBlue1 - 1
P2 P6 - SquareGreen3 - 2
P8 - SquareRed2 - 1

With a little more work, you could sort on hash values to get the output in the order you want.

[BillKSmith]

If you can depend on the fixed columns, use unpack the same way as split.

[killersquirel11]

Yes, I can depend on fixed columns more so than I can on the contents being nicely-formatted. Thanks for the quick replies.

[Anonymous Monk]

1 == @ARGV or die "One, and only one argument expected\n";

1 == @ARGV or die Usage();