Issues with Split

[cipher]

Hi, I am having some issues while creating a multidimensional hash. The issue is with split and not the hash itself. Here is my code

use strict;
use warnings;
use Data::Dumper; 

my %hash;

while (<DATA>) {
    chomp;
    my ($type, $restofstring) = /^type=(\w+) (.+)$/;
    for $restofstring(split){
    my ($key, $val) = split /=/, $restofstring;
    $hash{$type}{$key} = $val;
    }
}
print Dumper \%hash;

__DATA__
type=first a=1 b=2 c=3
type=second d=4 e=5 f=6
type=third g=7 h=8 i=9

The output is:

$VAR1 = {
          'third' => {
                       'h' => '8',
                       'type' => 'third',
                       'i' => '9',
                       'g' => '7'
                     },
          'first' => {
                       'type' => 'first',
                       'c' => '3',
                       'b' => '2',
                       'a' => '1'
                     },
          'second' => {
                        'd' => '4',
                        'e' => '5',
                        'type' => 'second',
                        'f' => '6'
                      }
        };

I was expecting the output to be like this.

$VAR1 = {
          'third' => {
                       'h' => '8',
                       'i' => '9',
                       'g' => '7'
                     },
          'first' => {
                       'c' => '3',
                       'b' => '2',
                       'a' => '1'
                     },
          'second' => {
                        'd' => '4',
                        'e' => '5',
                        'f' => '6'
                      }
        };

when I print $restofstring I only see "a=1 b=2 c=3", etc. I am not sure why $key, $value include the $type variable when I think I am exclusively splitting only on variale $restofstring. What am I doing wrong ?

[afoken]

my ($type, $restofstring) = /^type=(\w+) (.+)$/;
for $restofstring(split){

You are splitting the entire line read ($_), not what (.+) matched ($restofstring). And you are overwriting $restofstring.

You need a different loop variable, and you need to pass $restofstring as second argument to split.

Alexander

[cipher]

Thanks, I am still trying to get this fixed based on your recommendations. I will update this thread once I make any progress.

[graff]

Here is what afoken was talking about -- instead of this:

    my ($type, $restofstring) = /^type=(\w+) (.+)$/;
    for $restofstring (split) {
        my ($key, $val) = split /=/, $restofstring;
        $hash{$type}{$key} = $val;
    }

you should do this:

    my ($type, $restofstring) = /^type=(\w+) (.+)$/;
    for $token ( split ' ', $restofstring ) {
        my ($key, $val) = split /=/, $token;
        $hash{$type}{$key} = $val;
    }

[duyet]

that would be :

    for my $pair ( split /\s+/, $restofstring )
    {
        my ($key, $val) = split /=/, $pair;
        $hash{$type}{$key} = $val;
    }

[cipher]

Thanks! it works. Appreciate your help.

[johngg]

Another way would be to pass each line of data into a series of nested maps to split on whitespace then on the equals to produce an anonymous hash (hashref) which is passed to a third map. There the value of the "type" key is preserved, the "type" key/value pair deleteed from the hashref and finally the preserved key, with its value being the hashref, passed into %hash.

use strict;
use warnings;

use Data::Dumper;

open my $inFH, q{<}, \ <<EOF or die $!;
type=first a=1 b=2 c=3
type=second d=4 e=5 f=6
type=third g=7 h=8 i=9
EOF

my %hash =
   map {
       my $key = $_->{ type };
       delete $_->{ type };
       ( $key => $_ );
       }
   map { { map { split m{=} } split } }
   <$inFH>;

close$inFH or die $!;

print Data::Dumper
   ->new( [ \ %hash ], [ qw{ *hash } ] )
   ->Sortkeys( 1 )
   ->Dumpxs();

The output.

%hash = (
          'first' => {
                       'a' => '1',
                       'b' => '2',
                       'c' => '3'
                     },
          'second' => {
                        'd' => '4',
                        'e' => '5',
                        'f' => '6'
                      },
          'third' => {
                       'g' => '7',
                       'h' => '8',
                       'i' => '9'
                     }
        );

I hope this is helpful.

Update: Revised wording, s/a series of/nested/.

[cipher]

Thanks JohnGG, I am not that familiar with map but I really appreciate your response and help. This community rocks!