Re: Looking for suitable spells to get open to return a filehandle from a module

[Athanasius]

Hello talexb,

You are passing in $fh as a scalar, then overwriting it in the line $fh = Symbol::gensym;, so $fh works correctly inside Extra::open but remains undef in the caller. You need to pass in a reference, and dereference it accordingly within Extra::open:

{
    my $fh;
    Extra::open ( \$fh, '>', 'extra-open.txt' ) or
        die "2. Open failed: $!";
    defined $fh or die "2. Filehandle not defined";
    print $fh "Extra open works fine.\n";
    close ( $fh );
}

package Extra;

use Symbol;

sub open
{
    my ( $fh, $direction, $filename ) = @_;
    
    $$fh = Symbol::gensym;
    open ( $$fh, $direction, $filename );
}

1;

In my (minimal) testing, this writes the correct messages to the two output files, and no error is generated.

Hope that helps,

[afoken]

package Extra;

use Symbol;

sub open
{
    my ( $fh, $direction, $filename ) = @_;
    
    $$fh = Symbol::gensym;
    open ( $$fh, $direction, $filename );
}

1;

I think this should work without explicit references:

sub open
{
    my (undef, $direction, $filename)=@_;

    $_[0]=Symbol::gensym;
    open ($_[0],$direction,$filename);
}

The trick is not to copy the alias in @_, but to directly use the alias. Maybe you need to extend open to have a prototype of ($$$).

Anyway, I would prefer a modified open function to return a handle or undef instead of a boolean, so:

sub open
{
    my ($direction,$filename)=@_;
    open my $h,$direction,$filename or return;
    # alternatively: or die "Can't open $filename: $!";
    return $h;
}

Alexander

[AnomalousMonk]

What is the effect of the invocation of Symbol::gensym? This code seems to work just fine without it both with aliasing and with an automatic reference via a prototype (also minimally tested):
t_extra_open.pl:

use warnings;
use strict;

use Extra;

{
    my $filename = 'extra-open.txt';

    Extra::open my $fh, '>', $filename
        or die "opening '$filename' for write: $!";
    defined $fh or die "write filehandle not defined";
    print $fh "Extra open works just fine \n";
    print $fh "at ", scalar(localtime), "\n";
    close $fh or die "closing '$filename' after write";

    undef $fh;
    Extra::open $fh, '<', $filename
        or die "opening '$filename' for read: $!";
    defined $fh or die "read filehandle not defined";
    print '<<', <$fh>, '>>';
    close $fh or die "closing '$filename' after read";

}

Extra.pm:

package Extra;

sub open {  # works

    my (undef, $direction, $filename) = @_;

    return open $_[0], $direction, $filename;

    }

# sub open (\$@) {  # works
#
#     my ($sr_fh, $direction, $filename) = @_;
#
#     return open $$sr_fh, $direction, $filename;
#
#     }

1;

(Tested under ActiveState 5.8.9 and Strawberry 5.14.4.1.)

[afoken]

What is the effect of the invocation of Symbol::gensym?

In this case, just a lazily copied expression. Quoting Symbol:

Symbol::gensym creates an anonymous glob and returns a reference to it. Such a glob reference can be used as a file or directory handle.

And that's it. It was needed in ancient perls. Perl 5.6.1 introduced autovivication for file and directory handles (see perl561delta), so Symbol::gensym is technically no longer needed. open my $fh, ... or open local $fh, ... is sufficient.

Alexander

[Laurent_R]

I would prefer a modified open function to return a handle

I agree that creating the filehandle within the sub and returning it to the caller is by far the simplest and the best solution (unless I miss something from the OP requirement).

[talexb]

Brilliant. Thanks!