I wanted to add a note on PowerPoint, as when I googled for "powerpoint Win32::OLE tutorial" this node was the very top link!

So here is how I've gone about creating a PowerPoint presentation.

First load the modules:

use Win32::OLE;
use Win32::OLE::Const 'Microsoft Office';
use Win32::OLE::Const 'Microsoft PowerPoint';
use strict;
[download]

..then setting warnings as per the Excel tutorial..

$Win32::OLE::Warn = 3; # die on errors
[download]

Next, name the file that will be saved:

my $filename = "c:\\temp\\testpower.ppt";
[download]

.. and then fire up the PowerPoint application

print( "Starting Powerpoint Object\n" );
my $power = Win32::OLE->GetActiveObject('Powerpoint.Application') ||
    Win32::OLE->new('Powerpoint.Application', 'Quit');
[download]

Create a presentation (much like creating a workbook in Excel)

print( "Creating a presentation\n" );
my $ppt = $power->Presentations->Add();
$ppt->SaveAs($filename);
[download]

(and save!).

Create a slide (like creating a worksheet in Excel)

print( "Creating a slide\n" );
my $slide = $ppt->Slides->Add(1, ppLayoutBlank);
$ppt->SaveAs($filename);
[download]

Insert a picture into my slide

my $pname = 'C:\WINNT\Web\Wallpaper\Fall Memories.jpg';
my $shape = $slide->Shapes->AddPicture( $pname, msoFalse, 
                                        msoTrue, 20, 1 );
# scale to 50% of original size
$shape->ScaleHeight( 0.5, msoTrue, msoScaleFromTopLeft );
$shape->ScaleWidth( 0.5, msoTrue, msoScaleFromTopLeft );
$ppt->SaveAs($filename);
[download]

Insert a table

print( "Adding a 4 wide by 3 high table\n" );
my $table = $slide->Shapes->AddTable( 3, 4, 1, 100 );
my $columns = $table->Table->Columns->Count;
my $rows = $table->Table->Rows->Count;

for ( my $row = 0; $row < $rows; $row++ ) {
    for ( my $col = 0; $col < $columns; $col++ ) {
        my $cell = $table->Table->Rows($row+1)->Cells($col+1);

        my $textframe = $cell->Shape->TextFrame;
        $textframe->TextRange->{Text} = "$col,$row";
        $textframe->TextRange->Font->{Bold} = msoFalse;
        $textframe->TextRange->Font->{Name} = "Arial";
        # set text size AFTER changing text
        $textframe->TextRange->Font->{Size} = "12";
    }
}
$ppt->SaveAs($filename);
[download]

There's a lot more that can be done, of course, and the best reference is at MSDN's Visual Basic Reference for PowerPoint. All the methods and properties used here are listed there. In addition, when calling a method, you often can leave parameters off the end and defaults will be used for you.

Another note to add.. if you're not running PowerPoint at the time this script is run, then it will happen in the background. The only way to know for sure if it worked is to open the file you created and visually verify everything was added.

---

---

• Are you posting in the right place? Check out Where do I post X? to know for sure.
• Posts may use any of the Perl Monks Approved HTML tags. Currently these include the following:

  <code> <a> <b> <big> <blockquote> <br /> <dd> <dl> <dt> <em> <font> <h1> <h2> <h3> <h4> <h5> <h6> <hr /> <i> <li> <nbsp> <ol> <p> <small> <strike> <strong> <sub> <sup> <table> <td> <th> <tr> <tt> <u> <ul>

• Snippets of code should be wrapped in <code> tags not <pre> tags. In fact, <pre> tags should generally be avoided. If they must be used, extreme care should be taken to ensure that their contents do not have long lines (<70 chars), in order to prevent horizontal scrolling (and possible janitor intervention).
• Want more info? How to link or How to display code and escape characters are good places to start.