What's wrong with \b? It's only needed at the beginning, since you have the closing quote to mark the end. (UPDATED below with fancier pattern)

Test code:

#!/usr/bin/perl
use strict;
use warnings;
use diagnostics;

my $alpha = qq(alpha="first");
my $beta  = qq(beta="second");
my $gamma = qq(gamma="third");

my $s1 = qq($alpha $beta $gamma);
my $s2 = qq($alpha $gamma $beta);
my $s3 = qq($beta $alpha $gamma);

#my $pat = qr/\b(beta="second")/;
my $pat = qr/(?:\A|\s)(beta="second")(?:\s|\Z)/;

print "s1: \'$s1\', match=".($s1 =~ $pat ? $1 : "nada")."\n";
print "s2: \'$s2\', match=".($s2 =~ $pat ? $1 : "nada")."\n";
print "s3: \'$s3\', match=".($s3 =~ $pat ? $1 : "nada")."\n";
[download]

s1: 'alpha="first" beta="second" gamma="third"', match=beta="second"
s2: 'alpha="first" gamma="third" beta="second"', match=beta="second"
s3: 'beta="second" alpha="first" gamma="third"', match=beta="second"
[download]

Works fine for beta, but the same code would not work for alpha. The point is, I don't know the location in the string of the word I'm matching. You're right that, in this case, I don't need to worry about the end of string. But still, I'd like to be able to give my users a general-purpose rule which works even without the quotes.

See updated code above using fancier pattern. (Why do you think think the original would not work for alpha?)

Some solutions:

• /(?:\A|\s)(beta="second")(?:\s|\Z)/
  [download]

• /(?<!\S)(beta="second")(?!\S)/
  [download]

• " $_ " =~ /\s(beta="second")\s/
  [download]

However, I don't see why the following doesn't suffice:

/\b(beta="second")/
[download]

You're obviously not writing a validator, and the double quote mark is unambiguously the end of what you want to match. The \b at the start is necessary to avoid accidentally matching alphabeta="fourth", but there's no need for anything similar at the end since the double quote can't be part of anything else.

Update: I just noticed

a general-purpose rule which works even without the quotes.

Again, no problem

/\b$id=(?:"[^"]*"|\w+)/
[download]

\b and \s don't work if the substring to be matched comes at the beginning of the string. There are, as you pointed out, ways to deal with this, but they are too complicated for my users.

\b and \s don't work if the substring to be matched comes at the beginning of the string.

If you're going to contradict, please test first. You would have found yourself wrong. The beginning and the end of the string count as whitespace for \b. This is documented and observable:

$_ = 'alpha="first" beta="second" gamma="third"';

for my $id (qw( alpha beta gamma )) {
    my ($val) = /\b$id=("[^"]*"|\w+)/
        or next;

    print("$id: $val\n");
}
[download]

alpha: "first"
beta: "second"
gamma: "third"
[download]

Or

$_ = 'alpha="first" beta="second" gamma="third"';

while (/(\w+)=("[^"]*"|\w+)/g) {
    print("$1: $2\n");
}
[download]

alpha: "first"
beta: "second"
gamma: "third"
[download]

>perl -wMstrict -le
"my $pre  = qr{ \A | \s }xms;
 my $post = qr{ \s | \z }xms;
 my $str  = q{foo='123' barfoo='987' bar='555'};
 for my $user_supplied (@ARGV) {
   my $rx = qr{ $pre \Q$user_supplied\E $post }xms;
   $str =~ m{ ($rx) }xms;
   print qq{[$user_supplied] matches }, $1 ? qq{[$1]} : q{nothing};
   }
"
foo='123' bar='555' barfoo='987' foo='987'
[foo='123'] matches [foo='123' ]
[bar='555'] matches [ bar='555']
[barfoo='987'] matches [ barfoo='987' ]
[foo='987'] matches nothing
[download]

That's a good idea which I hadn't thought of. Unfortunately it is not necessarily so easy to do in my application because the user is allowed to write any valid Perl regex. Maybe I can define a new class of matching which does have this wrapping.

The approach still 'works' (in some sense) because the user can only supply the regex in the form of a string which is later compiled into and/or included into the compilation of a real regex object. Just don't use the metacharacter escaping mechanism of  \Q...\E or the quotemeta function.

However, there seems to be another problem here: you say users may write any valid Perl regex, but you have also said (or implied) that they are not required to know anything about regexes nor to suffer any danger of exposure to such knowledge. This seems like a prescription for a major headache, if not disaster. User-supplied patterns would usually be validated or meta-quoted up the wazoo.