Beefy Boxes and Bandwidth Generously Provided by pair Networks
Problems? Is your data what you think it is?
 
PerlMonks  

Re^5: Hash of Hashes from file

by Cristoforo (Curate)
on Apr 03, 2012 at 20:57 UTC ( [id://963314]=note: print w/replies, xml ) Need Help??


in reply to Re^4: Hash of Hashes from file
in thread Hash of Hashes from file

Yes, it should be possible but the syntax might get sticky. As scorpio17 says in this thread, what you want to do with the data is one the the deciding factors in how you want to store it. (Along with other factors). If the data is too large to load into memory, you may need to consider some of the suggestions offered by others here.

If the requirement is just to produce output like you provided, a Hash of Hashes may be a good choice. 

#!/usr/bin/perl
use strict;
use warnings;

my %data;

while (<DATA>) {
    my ($user, $site, $cat) = /"([^"]+)"/g;
    $data{$user}{$site} = $cat;
}

for my $user (keys %data) {
    my $href = $data{$user};
    print $user, "\n";
    print "\tWebsite: $_, Category: $href->{$_}\n" for keys %$href;
}

__DATA__
user="john" website="www.yahoo.com" type="Entertainment"
user="david" website="www.facebook.com" type="Social Networking"
user="john" website="www.facebook.com" type="Social Networking"
user="mike" website="www.google.com" type="Search Engines"

[download]
Output was: 
john
        Website: www.yahoo.com, Category: Entertainment
        Website: www.facebook.com, Category: Social Networking
mike
        Website: www.google.com, Category: Search Engines
david
        Website: www.facebook.com, Category: Social Networking

[download]
 Update: With a file this large, would it be likely for one user to visit the same website more than once?

Replies are listed 'Best First'.
Re^6: Hash of Hashes from file
by cipher (Acolyte) on Apr 05, 2012 at 01:12 UTC
    Yes users visit same websites multiple times. For this reason I added Key as string "Website" and value as the actual website.
[reply]
      I got the following output: 
      C:\Old_Data\perlp>perl t33.pl
david
        Website: www.facebook.com, Category: Social Networking
john
        Website: www.yahoo.com, Category: Entertainment
        Website: www.yahoo.com, Category: Entertainment
        Website: www.yahoo.com, Category: Entertainment
        Website: www.facebook.com, Category: Social Networking
mike
        Website: www.google.com, Category: Search Engines


Name: john
        Website Count
        www.yahoo.com       3
        www.facebook.com    1

        Type Count
        Entertainment       3
        Social Networking   1


Name: mike
        Website Count
        www.google.com      1

        Type Count
        Search Engines      1


Name: david
        Website Count
        www.facebook.com    1

        Type Count
        Social Networking   1

      [download]
      From this data: 
      user="john" website="www.yahoo.com" type="Entertainment"
user="john" website="www.yahoo.com" type="Entertainment"
user="john" website="www.yahoo.com" type="Entertainment"
user="david" website="www.facebook.com" type="Social Networking"
user="john" website="www.facebook.com" type="Social Networking"
user="mike" website="www.google.com" type="Search Engines"

      [download]
      Notice that there are quotes surrounding every field. The regular expression that captures these fields from the file would need to be changed if thats not the case.

      In my program I use 2 hashes - one to count the number of sites visited by each user, %count, and one to count each address and category (by user), %data. It seems to work OK for this small data set. 

      #!/usr/bin/perl
use strict;
use warnings;

my (%data, %count);

while (<DATA>) {
    my ($user, $site, $cat) = /"([^"]+)"/g;
    $data{$user}{ qq{$site$;$cat} }++;
    $count{$user}++;
}

for my $user (sort keys %data) {
    my $href = $data{$user};
    print $user, "\n";
    for my $key (keys %$href) {
        my $str = sprintf "\tWebsite: %s, Category: %s\n", split /$;/,
+ $key;
        print $str x $href->{$key};
    }
}

my @ordered = sort {$count{$b} <=> $count{$a}} keys %count;

print "\n\n";

for my $user (@ordered) {
    my $href = $data{$user};
    print "Name: $user\n\tWebsite Count\n";
    for my $key (sort {$href->{$b} <=> $href->{$a}} keys %$href) {
        printf "\t%-20s%d\n", (split /$;/, $key)[0], $href->{$key};
    }
    print "\n";
    print "\tType Count\n";
    for my $key (sort {$href->{$b} <=> $href->{$a}} keys %$href) {
        printf "\t%-20s%d\n", (split /$;/, $key)[1], $href->{$key};
    }
    print "\n\n";
}

      [download]
      The line $data{$user}{ qq{$site$;$cat} }++; uses a 'compound' key ($site and $cat joined by $;).

      Here is a dump of %data. 

      $VAR1 = {
          'john' => {
                      'www.yahoo.com‡˜Entertainment' => 3,
                      'www.facebook.com‡˜Social Networking' => 1
                    },
          'mike' => {
                      'www.google.com‡˜Search Engines' => 1
                    },
          'david' => {
                       'www.facebook.com‡˜Social Networking' =>
                     }
        };

      [download]

      Update: Whoops, that doesn't count the categories correctly :-(
      If there was another site with the same category, it wouldn't be totaled with the same category from another site.

[reply]
[d/l]
[select]
        Think I got it this time! I used the data structure that scorpio17 used (I printed out the dump here also). Output: 
        C:\Old_Data\perlp>perl t33.pl
$VAR1 = {
          'john' => {
                      'site' => [
                                  'www.yahoo.com',
                                  'www.yahoo.com',
                                  'www.yahoo.com',
                                  'www.facebook.com'
                                ],
                      'type' => [
                                  'Entertainment',
                                  'Entertainment',
                                  'Entertainment',
                                  'Social Networking'
                                ]
                    },
          'mike' => {
                      'site' => [
                                  'www.google.com'
                                ],
                      'type' => [
                                  'Search Engines'
                                ]
                    },
          'david' => {
                       'site' => [
                                   'www.facebook.com'
                                 ],
                       'type' => [
                                   'Social Networking'
                                 ]
                     }
        };
david
        Website: www.facebook.com, Category: Social Networking
john
        Website: www.yahoo.com, Category: Entertainment
        Website: www.yahoo.com, Category: Entertainment
        Website: www.yahoo.com, Category: Entertainment
        Website: www.facebook.com, Category: Social Networking
mike
        Website: www.google.com, Category: Search Engines


Name: john
        Website Count
        www.yahoo.com       3
        www.facebook.com    1

        Type Count
        Entertainment       3
        Social Networking   1


Name: mike
        Website Count
        www.google.com      1

        Type Count
        Search Engines      1


Name: david
        Website Count
        www.facebook.com    1

        Type Count
        Social Networking   1



C:\Old_Data\perlp>

        [download]
        And here is the code: 
        #!/usr/bin/perl
use strict;
use warnings;

my %data;

while (<DATA>) {
    my ($user, $site, $cat) = /"([^"]+)"/g;
    push @{ $data{$user}{site} }, $site;
    push @{ $data{$user}{type} }, $cat;
}

for my $user (sort keys %data) {
    my $site_ary = $data{$user}{site};
    my $type_ary = $data{$user}{type};
    print $user, "\n";
    for my $i (0 .. $#$site_ary) {
        printf "\tWebsite: %s, Category: %s\n", $site_ary->[$i], $type
+_ary->[$i];
    }
}
print "\n\n";

for my $user (sort by_count_desc keys %data) {
    my $site_ary = $data{$user}{site};
    my $type_ary = $data{$user}{type};
    my (%site_cnt, %type_cnt);
    $site_cnt{$_}++ for @$site_ary;
    $type_cnt{$_}++ for @$type_ary;
    
    print "Name: $user\n\tWebsite Count\n";
    for my $site (sort {$site_cnt{$b} <=> $site_cnt{$a}} keys %site_cn
+t) {
        printf "\t%-20s%d\n", $site, $site_cnt{$site};
    }
    print "\n";
    print "\tType Count\n";
    for my $type (sort {$type_cnt{$b} <=> $type_cnt{$a}} keys %type_cn
+t) {
        printf "\t%-20s%d\n", $type, $type_cnt{$type};
    }
    print "\n\n";
}

sub by_count_desc {
    @{$data{$b}{site}} <=> @{$data{$a}{site}};
}

__DATA__
user="john" website="www.yahoo.com" type="Entertainment"
user="john" website="www.yahoo.com" type="Entertainment"
user="john" website="www.yahoo.com" type="Entertainment"
user="david" website="www.facebook.com" type="Social Networking"
user="john" website="www.facebook.com" type="Social Networking"
user="mike" website="www.google.com" type="Search Engines"

        [download]
        Hope this helps, Chris

        Update: Added sub by_count_desc.

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom

Log In?
Username:
Password:

What's my password?
Create A New User
Domain Nodelet?

www.com | www.net | www.org
Node Status?
node history
Node Type: note [id://963314]
help
Chatterbox?
and the web crawler heard nothing...

How do I use this? • Last hour • Other CB clients
Other Users?
Others romping around the Monastery: (2)
As of 2024-04-20 04:11 GMT
Sections?
Information?
Find Nodes?
Leftovers?
    Voting Booth?

    No recent polls found