Re^5: Optional Arguments..?

[poj]

You can't store all the data you need like this ;

# declare a hash of array to prepare storage of all 
# variables to be encoded together
  my $HoA{$sitename} = ["$loginid", "$password", "$url"];
  open(FILEHANDLE, ">>passmgr.dat") 
    or die("The file cannot be opened!");
  my $encode = ST2614::encode($HoA, $ARGV[1]);
  print FILEHANDLE "$encode";
  close FILEHANDLE;

Consider using a tab delimiter record format like this ;

sitename1 loginid1 encoded_password1 url1
sitename2 loginid2 encoded_password2 url2
sitename3 loginid3 encoded_password3 url3

Then you can build a HoA from the file like this

my $key = $ARGV[1] || 'secretkey';
my %HoA=();
open IN, '<','passmgr.dat' 
   or die ("The file cannot be opened!");
while (<IN>){
  chomp;
  my ($sitename,$id,$enc_password,$url) = split "\t",$_;
  my $password = ST2614::decode($enc_password, $key);
  $HoA{$sitename} = [$id,$password,$url];
  # print "$sitename $id $password $url\n";
}

and save it to the file like this

open OUT, '>','passmgr.dat'
   or die ("The file cannot be opened!");
for my $sitename (sort keys %HoA){
  my $id = $HoA{$sitename}[0];
  my $enc_password = ST2614::encode($HoA{$sitename}[1], $key);
  my $url = $HoA{$sitename}[2];
  print OUT join "\t",$sitename,$id,$enc_password,$url,"\n";
}

poj

[Watergun]

Thanks for the reply!

But could you kindly explain what the code you provided does, and how does it work? As I'm very new to Perl, I don't understand some of the code yet.

If I am not wrong, you are only encoding the password, but my aim is to encode everything that the user entered.

[poj]

I have added some comments and changed it to encode/decode complete records i.e. all the data.

#!perl
use strict;
use ST2614;

my $key = $ARGV[1] || 'secretkey';
my %HoA=();

# open file to read
open IN, '<','passmgr.dat' 
   or die ("The file cannot be opened!");
   
# read records line at a time   
while (<IN>){
  chomp; # remove carriage return/line feed
  # decode record
  my $record = ST2614::decode($_, $key);
  # split records into fields on tab
  my ($sitename,$id,$password,$url) = split "\t",$record;
  # build hash of arrays
  $HoA{$sitename} = [$id,$password,$url];
  # print "$sitename $id $password $url\n";
} 

# open file to write
open OUT, '>','passmgr.dat'
   or die ("The file cannot be opened!");

# loop through HOA using key to extract values from array
for my $sitename (sort keys %HoA){
  my $id       = $HoA{$sitename}[0];
  my $password = $HoA{$sitename}[1];
  my $url      = $HoA{$sitename}[2];
  # build a record of fields seperated with tab
  my $record = join "\t",$sitename,$id,$password,$url;
  # store as encoded value
  print OUT ST2614::encode($record,$key)."\n";
}

hope this helps
poj