#!/usr/bin/env perl

use HTML::HTML5::Parser;
use Object::Tap -package => 'XML::Atom::Base';
use XML::Atom::Feed;
use XML::Atom::Entry;
use XML::Atom::Person;
use XML::LibXML 2.00;

my $list = HTML::HTML5::Parser
	-> new
	-> parse_file('http://mini-cb60.datenzoo.de/', { ignore_http_response_code => 1 })
	-> getElementsByTagName('dl')
	-> get_node(1);

my $feed = XML::Atom::Feed->new;
$feed->title('PerlMonks Chatterbox');
$feed->id('tag:buzzword.org.uk,2012:perlmonks:chatterbox');

my $dt;
foreach my $node ($list->getChildrenByTagName('*'))
{
	($dt = $node) && next if $node->tagName eq 'dt';

	$feed->add_entry(
		XML::Atom::Entry->new->tap(
			title  => [ $node->textContent ],
			id     => [ join ':', $feed->id, $dt->{id} ],
			author => [
				XML::Atom::Person->new->tap(
					name => [ $dt->getElementsByTagName('a')->get_node(1)->textContent ],
					uri  => [
						'http://www.perlmonks.org/'.
						$dt->getElementsByTagName('a')->get_node(1)->{href}
					],
				)
			],
			published => [
				$dt->getElementsByTagName('small')->get_node(1)->textContent,
			],
		)
	);
}

print $feed->as_xml;