Term::ANSIColor and printf - easy way to use them together

[bdalzell]

Is there an easy way to use Term::ANSIColor and printf together?

I want to output a formatted response to the terminal.

 printf works fine for this project but the text is monochrome. I would like to be able to highlight some of the text within a line of formatted output

This works but is not elegant:

#!/usr/bin/perl 
use strict; 
use Term::ANSIColor qw(:constants); 
{ local $Term::ANSIColor::AUTORESET = 1; 
 print BOLD "Dog record\n"; 
 my $nlabel = BLACK ."Name\:"; 
 my $dogname = RED ."Silkenswift Blaze of Chaos"; 
 my $pt = RED "DC ";
 my $ft = RED "LCM2 SORC GRC ";
 my $ot = RED "CD "; 

printf("%-14s %-41s %-20s \n","$nlabel $pt","$dogname","$ft $ot"); 
print BLACK ""; print BOLD "################################\n"; 
}

This is just an example. In the actual program variables are being used in the black text areas such as :

$thisdog{'name'}

[tobyink]

use Term::ANSIColor qw( colored );

printf(
    "%4s %8s %4s\n",
    colored('Hello', 'bright_yellow on_magenta'),
    colored('Hello World', 'white on_blue'),
    colored('XXX', 'green on_white'),
);

[bdalzell]

Thank you so much, that does work!

[johngg]

Another way using :constants is to either interpolate the BOLD, RED, RESET, whatever into the string using the @{ [ ... ] } construct or make them separate items in the printf with their own %s format specifier. Remember that the constants return ANSI control character sequences that will "take" some of the format width in the first method. That doesn't matter on the first line but would become trickier for the column items of the second line.

use strict;
use warnings;

use Term::ANSIColor qw{ :constants };

printf qq{%s\nName:%s%-9s%-41s%s%-14s%s%-6s%s\n},
   qq{@{ [ BOLD ] }Dog record@{ [ RESET ] }},
   RED, q{DC},
   q{Silkenswift Blaze of Chaos},
   GREEN, q{LCM2 SORC GRC},
   BLUE, q{CD},
   RESET;

I hope this is helpful.