Re^2: Perl::Critic policy for common Log::Log4perl mistake

[andreas1234567]

The following Benchmarked code snipped shows a 10-15% performance increase by simply wrapping the log calls. Note that it is just a scalar being logged (suppressed, actually), not even an array, an especially not a super-long array. I don't find it to be particularly bloated either:

#!/usr/bin/perl

use strict;
use warnings;

use Log::Log4perl;
use Benchmark qw(cmpthese);
use Config;

my $conf = q(
 log4perl.category.bench  = INFO, ScreenAppender

  log4perl.appender.ScreenAppender         = Log::Log4perl::Appender::
+Screen
  log4perl.appender.ScreenAppender.stderr  = 1
  log4perl.appender.ScreenAppender.layout  = PatternLayout
  log4perl.appender.ScreenAppender.layout.ConversionPattern=[%p] %d %F
+:%L - %m%n
  log4perl.appender.ScreenAppender.Threshold  = DEBUG
);

Log::Log4perl::init(\$conf);
my $log = Log::Log4perl::get_logger("bench");

sub fib_log_buffer {
  my @fibonacci = (0, 1);
  my ($n, $sum) = (1, 0);
  while ($n < 1_000_000) {
    $log->debug(qq{n:$n});
    $n = $fibonacci[$#fibonacci] + $fibonacci[ $#fibonacci - 1 ];
    push @fibonacci, $n;
    $sum += $n if (($n % 2) == 0);
  }
  $log->debug(qq{n:$n});
  return $sum;
}

sub fib_log_buffer_is_chk {
  my @fibonacci = (0, 1);
  my ($n, $sum) = (1, 0);
  while ($n < 1_000_000) {
    $log->debug(qq{n:$n}) if $log->is_debug();
    $n = $fibonacci[$#fibonacci] + $fibonacci[ $#fibonacci - 1 ];
    push @fibonacci, $n;
    $sum += $n if (($n % 2) == 0);
  }
  $log->debug(qq{n:$n}) if $log->is_debug();
  return $sum;
}


# ------ main ------
print $Config{archname} ."\n";

cmpthese(
  -1,
  {
    'fib_log_buffer' => sub { fib_log_buffer() },
    'fib_log_buffer_is_chk' => sub { fib_log_buffer_is_chk() },
  }
);

__END__

 $ perl  l4p_bench.pl
 x86_64-linux
                          Rate        fib_log_buffer fib_log_buffer_is
+_chk
 fib_log_buffer        15605/s                    --                  
+-11%
 fib_log_buffer_is_chk 17454/s                   12%                  
+  --

[jethro]

Then add this to your test:

sub fib_no_log {
  my @fibonacci = (0, 1);
  my ($n, $sum) = (1, 0);
  while ($n < 1_000_000) {
    $n = $fibonacci[$#fibonacci] + $fibonacci[ $#fibonacci - 1 ];
    push @fibonacci, $n;
    $sum += $n if (($n % 2) == 0);
  }
  return $sum;
}

...

    'fib_no_log' => sub { fib_no_log() },

and you will get this result:

                        Rate fib_log_buffer fib_log_buffer_is_chk    f
+ib_no_log
fib_log_buffer        11712/s             --                  -13%    
+      -68%
fib_log_buffer_is_chk 13525/s            15%                    --    
+      -63%
fib_no_log            36540/s           212%                  170%    
+        --

Why? Because even the call to is_debug takes twice as long as the rest, the "meat" of your loop. Obviously you should have a perl_critic rule to warn from use of log4perl at all. Or avoid artificial benchmarks ;-)

[andreas1234567]

Having logging and the ability to alter logging in run-time is in this case an important requirement. Removing logging is of course faster, but also makes the code irrelevant.

The objective is to allow for logging and make it reasonably fast.