http://www.perlmonks.org?node_id=1006467


in reply to Re^2: Moose "unions" and inheritance
in thread Moose "unions" and inheritance

"I would like to ask what is "caution" here?"

package Person {
  use Moose;
  has name => (is => 'ro', isa => 'Str');
  sub introduce_yourself {
    my $self = shift;
    printf("My name is %s\n", $self->name);
  }
}

package SecretAgent {
  use Moose;
  extends 'Person';
  # secret agents have many aliases
  has '+name' => (isa => 'ArrayRef');
}

my $bond = SecretAgent->new(
  name => ['James Bond', 'Burt Saxby', 'David Somerset'],
);
$bond->introduce_yourself;

[download]

You see the problem?

Making a type constraint tighter (e.g. if the parent class wants a Num, and the child class restricts it to an Int) should usually be just fine. Making it looser requires more caution. The author of the SecretAgent class needs to check which methods of Person assume that name is a string, and override them all.

package SecretAgent {
  use Moose;
  extends 'Person';
  # secret agents have many aliases
  has '+name' => (isa => 'ArrayRef');
  sub introduce_yourself {
    my $self    = shift;
    my @names   = @{ $self->name };
    my $name    = $names[ rand @names ];
    my $surname = (split / /, $name)[-1];
    printf("The name's %s, %s\n", $surname, $name);
  }  
}

[download]
perl -E'sub Monkey::do{say$_,for@_,do{($monkey=[caller(0)]->[3])=~s{::}{ }and$monkey}}"Monkey say"->Monkey::do'

Replies are listed 'Best First'.
Re^4: Moose "unions" and inheritance
by remiah (Hermit) on Dec 01, 2012 at 00:22 UTC

    Thanks for good example and clear explanation...

    So, all methods of Person using name attribute get troubled.

    At first I thought "around" at SecretAgent will work somehow, but "name" is already overrided and it is "ArrayRef" at Person's introduce_yourself method.

    This is really caution for me.

    Read more... (2 kB)

[reply]
[d/l]

In Section Seekers of Perl Wisdom