I whipped this up today to solve a problem that I deal with all the time. We have hundreds if not thousands of IP addresses on our network along with a very dynamic data center. What I mean by dynamic is hosts are always being added and with others being removed.

So the system guys come to me all the time and ask me for one or more IP addresses on a given network. My group manages DNS and IP addresses (as opposed to the network team for some reason) and for some reason they like to come to me in particular for those requests.

The normal process calls for combing through the DNS zone files and looking for a hole in the address range that isn't being used. Enough of that.. computers work for me not the other way around!

Here's what I came up with:

#!/usr/bin/perl -w 
$|=1;
use strict;
use Net::Ping;
use Net::Netmask;
use Net::DNS;
use Getopt::Long;

my @blocks=();
my $outfile="";

my $dns = Net::DNS::Resolver -> new;

my $res = GetOptions("net=s",\@blocks,
                     "out=s",\$outfile
                     );

$outfile="candidates.txt" unless $outfile;

@blocks=split(",",join(",",@blocks));

foreach my $i(0..$#blocks){
  unless ($blocks[$i] =~ m@^\d+\.\d+\.\d+\.\d+/\d+$@){
    $blocks[$i] = $blocks[$i] . "/24";
  }
}

open FOUT,sprintf("> %s",$outfile) or die "$outfile: $!";

my $p = Net::Ping->new();

foreach my $block(@blocks){
  my $net = Net::Netmask->new($block);
  foreach my $ip($net->enumerate()){
      next if $ip =~ m@\.0$@;
      next if $dns->search($ip);
    printf "%s\r",$ip;
    unless ($p->ping($ip,1)){
      printf FOUT "%s\n",$ip;
    }
  }
}

[download]